Hi Xiong,

To convert FHIR R4 to SDA you have to use this helper class :

HS.FHIR.DTL.Util.HC.FHIR.SDA3.Process

So if you want to convert an json FHIR file to SDA, you have to read the file from a business service cast you file to one of this message and send it to the helper class.

Here is and Business service example of reading fhir json files :

Class BS.FHIRFileService Extends Ens.BusinessService
{

Parameter ADAPTER = "EnsLib.File.InboundAdapter";

Property TargetConfigNames As %String(MAXLEN = 1000) [ InitialExpression = "BusinessProcess" ];

Parameter SETTINGS = "TargetConfigNames:Basic:selector?multiSelect=1&context={Ens.ContextSearch/ProductionItems?targets=1&productionName=@productionId}";

Method OnProcessInput(pDocIn As %RegisteredObject, Output pDocOut As %RegisteredObject) As %Status
{
    set status = $$$OK

    try {

        set pInput = ##class(HS.FHIRServer.Interop.Request).%New()
        set tQuickStream = ##class(HS.SDA3.QuickStream).%New()
        do tQuickStream.CopyFrom(pDocIn)
        set pInput.QuickStreamId= tQuickStream.Id


        for iTarget=1:1:$L(..TargetConfigNames, ",") {
            set tOneTarget=$ZStrip($P(..TargetConfigNames,",",iTarget),"<>W")  Continue:""=tOneTarget
            $$$ThrowOnError(..SendRequestSync(tOneTarget,pInput,.pDocOut))
        }
    } catch ex {
        set status = ex.AsStatus()
    }

    Quit status
}

}

You can find more information from this documentation :

https://docs.intersystems.com/irisforhealthlatest/csp/docbook/Doc.View.cls?KEY=HXFHIR_transforms#HXFHIR_transforms_bp_fhirsda

Hi Lucas,

A simple solution to you question can be this :

Property numDossiersMER As list Of %Integer(SQLPROJECTION = "table/column", STORAGEDEFAULT = "array");

Index numDossiersMERIdx On numDossiersMER(ELEMENTS);

With those parameters you can achieve :

• 'As list Of %Integer' allows you to use the Insert() in ObjectScript and 'for some %element' in SQL command
• 'SQLPROJECTION = "table/column"' allows you to display the table as a column (note, the column does not appear in a select * it must be specified : select numDossierMER, numDossiersMER from User_TestList_Data.Titre )
• 'STORAGEDEFAULT = "array"' allows a separate table for the normalized representation
• 'Index numDossiersMERIdx On numDossiersMER(ELEMENTS);' bring the ability to use index on values with this SQL query :

select numDossierMER, numDossiersMER from User_TestList_Data.Titre
where
for some %element(numDossiersMER) (%Value in (345))

Hi Cindy,

To deploy your services, routes and plugins to another environment you can use CI/CD with postman (newman)

Some examples here :

• https://github.com/grongierisc/iam-training/tree/main#12-cicd

Another possibility is to use deck (decK helps manage Kong’s configuration in a declarative fashion) from kong

• https://docs.konghq.com/deck/

I haven't tried this one, I can't give you feedback on it.

If I understand correctly, you want to replace an HTTP Header basic auth with a bearer token. If the bearer token is static, you can implement a solution like this:

• https://github.com/grongierisc/iam-training/tree/training#6-third-add-our-own-authentication

If it is dynamic, I think you will have to develop your own plug-in:

• https://github.com/grongierisc/iam-training/tree/training#11-plugins

A good base to start working on could be this plugin:

• https://github.com/grongierisc/kong-plugin-jwt-crafter

Hi,

What you can do is a snapshot of this ResultSet.

Then use the global of this snapshot for another Operation :

Get snapshot global :

Method OnGetSnapshot(pRequest As Ens.Request, Output pResponse As Ens.StringResponse) As %Status
{
	set tStatus = $$$OK
	
	try{
		
		set pResponse = ##class(Ens.StringResponse).%New()
				
		set tQuery = "SELECT *  FROM [sqlserver].[dbo].[whatever] "
 
		//$$$TRACE(tQuery)		
		Set pSnap = ##class(EnsLib.SQL.Snapshot).%New()
		
		//size of snapshot
		// -1 = Max
		set pSnap.MaxRowsToGet = -1
				
		$$$ThrowOnError(..Adapter.ExecuteQueryBatch(pSnap,tQuery,1000))
		
		$$$ThrowOnError(pSnap.%Save())
		
	
		set pResponse.StringValue = pSnap.%GblRef	
			
	}
	catch exp
		{
			Set tStatus = exp.AsStatus()
		}
	Quit tStatus
}

Use snapshot global :

Method UseSnapshot(pRequest As Ens.StringRequest, Output pResponse As Ens.Response) As %Status
{
	
	set status = $$$OK
	
	try {
		set pResponse = ##class(Ens.Response).%New()

		set nRow = 0
		set tSequence = 0
		
		//Get SnapShot
		Set tSnap = ##class(EnsLib.SQL.Snapshot).%New()
		set tSnap.%GblRef = pRequest.StringValue // use of global SnapShot
		set tSnap.%CurrentRow = 0
		set tSnap.FirstRow = 1
		set tSnap.MaxRowsToGet = -1
		
		$$$TRACE("MaxRowsToGet :  "_tSnap.RowCountGet())

				while tSnap.Next() {
					try {
							set nRow = nRow + 1
							set tSequence = tSequence + 1

                            set i = 0

                            set i = i + 1
                            set tParam(i) = tSnap.Get("Col1")

                            
                            set i = i + 1
                            set tParam(i) = tSnap.Get("Col2")

                       
                            set i = i + 1
                            set tParam(i) = tSnap.Get("Col3")

                           
                            set i = i + 1
                            set tParam(i) = tSnap.Get("ColX")

                            set tParam = i

							set tQuery = "UPDATE Whatever  "_
										"SET   "_
										"Col1 = ?  "_
										",Col2 = ?  "_
										",Col3 = ?  "_
										" WHERE ColX = ?  " 
														
							
							$$$ThrowOnError(..Adapter.ExecuteUpdateParmArray(.tResult,tQuery,.tParam))

						} catch exSnap {
                            // Update exeption
						}
			
		}
		
		
	} catch ex {
		set status = ex.AsStatus()
	}
	return status
}

Furthermore, If you have big table to query/insert in JDBC consider this ZPM module : https://github.com/grongierisc/BatchSqlOutboundAdapter

Hi Yuri,

Not now but it's plan to be in the future, may be next year.

If you need an how-to de develop an interoperability production check this git.

https://github.com/grongierisc/formation-template

It's in french but you will have a lot of gif to get throw the tuto and build a CSV parser and drop the file in the database with transformations.

Hi Paul,

Hi Yakov,

Have you tried to extend you target message by %SerialObject rather than %RegistredObject.

In fact, %RegistredObject are in memory object and can't be transmitted in Messages.

More details in this documentation : https://docs.intersystems.com/irisforhealthlatest/csp/docbook/DocBook.U…

Hi Ravikumar,

All can be done in InterSystems IRIS with almost no code.

Have a look at this demo to convert HL7v2 to FHIR : https://openexchange.intersystems.com/package/FHIR-HL7v2-SQL-Demo

For JSON/XML to FHIR, you can have a look here : https://github.com/grongierisc/HL7ToJson

For HL7 SIU, the same can be achieved with the first link.

For CDA/FHIR you have example here : https://github.com/grongierisc/FHIRaaS/blob/master/src/Interop/BP/CCDAT…

If you need more help, let me know.

Hi, you have to use irisinstall with elevated privileges.  

cf: https://docs.intersystems.com/irisforhealthlatest/csp/docbook/Doc.View…