That's correct (although from your example I would use $get(%request.Data("Q31",1)) over the "Get" method). I had another look and an assumption I had made in my previous post was partially incorrect. At least in questionnaires you can safely check the IsNew property of %UDF - this is correctly set when a questionnaire is created using either an API or through the UI. This value is derived from a variable that is set at the very top of the save so it allows us to identify a new added record. Here is a fairly simple (if a little crude) example:

ClassMethod Test()
{
	tstart
	do ..GetAPI(.objAPI)
	set objAPI.QUESPAPatMasDR = 5878
	
	set objAPI.QUESPAAdmDR = 11480
	set objAPI.Q01 = "Y"
	set rc = objAPI.Save()
	zwrite {"Q01":(objAPI.Q01)}
	set id = objAPI.ID
	kill objAPI
	set obj = ##class(questionnaire.QAUXXARP).%OpenId(id)
	
	zwrite {"Q01":(obj.Q01)}
	kill obj
	do ..GetAPI(.objAPI)	
	set rc = objAPI.Open("",id)
	set objAPI.Q01 = "Y"
	set rc = objAPI.Save()
	zwrite {"Q01":(objAPI.Q01)}
	kill objAPI
	set obj = ##class(questionnaire.QAUXXARP).%OpenId(id)
	zwrite {"Q01":(obj.Q01)}
	trollback
}

ClassMethod OnAfterSave() As %Boolean
{
	#dim %UDF as websys.UDFExt.TrakEvent
	set sc = $$$OK
	write !,"%UDF.IsNew = "_%UDF.IsNew,!
	if %UDF.IsNew {
		set obj = ##class(questionnaire.QAUXXARP).%OpenId(%UDF.Id,,.sc)
		if $isobject(obj) {
			set obj.Q01 = "N"
			set sc = obj.%Save()
		}
	}
	if $$$ISERR(sc) {
		do %UDF.Message.Status(sc)
	}
	return 1
}

do ##class(Custom.AUXX.UDF.questionnaire.QAUXXARP).Test()

%UDF.IsNew = 1
{"Q01":"Y"}  ; <DYNAMIC OBJECT>
{"Q01":"N"}  ; <DYNAMIC OBJECT>

%UDF.IsNew = 0
{"Q01":"Y"}  ; <DYNAMIC OBJECT>
{"Q01":"Y"}  ; <DYNAMIC OBJECT>

As you can see, the value of "Q01" is only set to "N" on the first save and is not updated afterwards.

Ah. Thanks for clarifying. That makes a bit more sense now but also raises another question. Are you creating the questionnaire through an API call, or is the questionnaire being added/updated as a result of an API call to a different component? If it's the former, you should just be able to populate the property when it's created. 

I can't think of any reason why OnBeforeSave wouldn't fire in any case. I can have a look on Monday when I'm in front of my work computer. I've done similar to what you're trying to do and I would usually set a flag using a PPG in OnBeforeSave if %request.Data("ID",1)="" and then check that in the OnAfterSave and update the item then. Alternatively if there's no ID (like above), you could set %request.Data(<component item name>,1) = 1 in OnBeforeSave and the %request value would be used when it populates the object values to save. 

Using a device mnemonic routine and redirecting IO also seems to work. I used this very basic routine to log to IO:

ZJES01	;
rchr(c)      quit
	#;Read a string - we don't care about reading
rstr(sz,to)  quit
	#;Write a character - call the output label
wchr(s)      do output($char(s))  quit
	#;Write a form feed - call the output label
wff()        do output($char(12))  quit
	#;Write a newline - call the output label
wnl()        do output($char(13,10))  quit
	#;Write a string - call the output label
wstr(s)      do output(s)  quit
	#;Write a tab - call the output label
wtab(s)      do output($char(9))  quit
	#;Output label - this is where you would handle what you actually want to do.
	#;  in our case, we want to write to str
output(s) set ^ZJES($increment(^ZJES))=s quit

And then used the following classmethod to test:

ClassMethod TestRedirect()
{
	
	set MnemonicRoutine = ##class(%Device).GetMnemonicRoutine()
	use $io::("^ZJES01")
	set RedirectIO=##class(%Device).ReDirectIO(1)
	do ..PythonPrint()
	do ##class(%Device).ReDirectIO(RedirectIO)
	use $io::("^"_MnemonicRoutine)
	quit
}

Which gave me:

zwrite ^ZJES
^ZJES=3
^ZJES(1)="Python print this line to the buffer"
^ZJES(2)=$c(13,10)
^ZJES(3)="IRIS write this line to the buffer"

It's probably worth mentioning that this was always the limit. Prior to IRIS 2020.1 (from memory) any characters after the first 31 were just ignored, so in the above example the global would be truncated to ^Jobcosting.JobActivityGroupGrou. There is now a hard stop in the class compiler that prevents global names longer than the limit as there was the potential for truncated global names to clash.

In Studio if you go to "Options"-> "Editor" -> "Keyword Expansion", you can change whether it uses uppercase, lower case, mixed case or retains the original case when you CTRL+E

You could improve that further by using the 3 parameter version of $order to fetch "Data". i.e:

Set Sub3=$Order(^Trans(Sub1,Sub2,Sub3))
If Sub3="" Quit
Write ?6,Sub3," = "
Set Data=(^Trans(Sub1,Sub2,Sub3))
Write Data,!

Becomes:

Set Sub3=$Order(^Trans(Sub1,Sub2,Sub3),1,Data)
If Sub3="" Quit
Write ?6,Sub3," = ",Data
Write Data,!