See more here: Evaluating XPath Expressions

Let's try to guess the return value of method t1().

To be honest I don't really understand the point which the author wanted to convey. Maybe it's the lack of English.

ClassMethod t3(ByRef pA, ByRef pB) [ ProcedureBlock = 1 ]
{
  set pA=4, pB=5
  set x=$increment(pA)*$increment(pB)
}

Hi Ponnumani.

I would like to make a number of clarifications:

• VALUELIST = "A A- B B- O" -> VALUELIST = " A A- B B- O"
• it is necessary to consider the order of the fields in the global on the basis of Storage. For example, I have following Storage:
  

  <Data name="samplexlsconversionDefaultData">
  <Value name="1">
  <Value>%%CLASSNAME</Value>
  </Value>
  <Value name="2">
  <Value>name</Value>
  </Value>
  <Value name="3">
  <Value>DOB</Value>
  </Value>
  <Value name="4">
  <Value>address</Value>
  </Value>
  <Value name="5">
  <Value>PhoneNumber</Value>
  </Value>
  <Value name="6">
  <Value>BloodGroup</Value>
  </Value>
  </Data>

• need to add check for the presence of double quotes in strings, e.g. bla"bla
• the date format for CSV should not be in the internal Caché format, because the date 37893 to users of other system/DBMS nothing says unlike e.g. 1944-09-30.

I still prefer to use built-in tools when they are there, rather than reinventing the wheel.

Class User.samplexlsconversion Extends (%Persistent, %Populate)
{

Property name As %String;

Property DOB As %Date;

Property address As %String;

Property PhoneNumber As %Numeric;

Property BloodGroup As %String(VALUELIST = " A A- B B- O");

ClassMethod TestExport2CSV()
{
  
  d ..%KillExtent()
  d ..Populate(1000)
  
  s tmp=..%OpenId(1)
  s tmp.name=tmp.name_$c(34)
  d tmp.%Save()
  
  s tmp=..%OpenId(2)
  s tmp.name=$c(34)_tmp.name_$c(34)
  d tmp.%Save()

  s mgr = ##class(%SQL.Export.Mgr).%New()
  s mgr.FileName = "c:\Temp\test.csv"
  s mgr.ClassName = ..%ClassName(1)
  s mgr.TableName = $$$CLASSsqltablename($$$gWRK,mgr.ClassName)
  s mgr.Delimiter = ","
  s mgr.StringQuote = $c(34)
  s mgr.DateFormat = 3
  s mgr.TimeFormat = 1
  s mgr.TimeStampFormat = 1
  s mgr.NoCheck = $$$YES
  s mgr.HasHeaders = $$$YES
  
  s cols="Name:S;Address:S;PhoneNumber:N;BloodGroup:S;DOB:D"
  f i=1:1:$l(cols,";") {
    s c=$p(cols,";",i)
    d mgr.ColumnNames.Insert($p(c,":",1))
    d mgr.ColumnTypes.Insert($p(c,":",2))
  }
  
  d mgr.Export()
}
}

Below are two ways without additional permissions on %DB_CACHESYS:

  #include %systemInclude
  n
  try{

    s sslName="Test"

    w "1) GetSSLConfigList^%SYS.SECURITY1(.SSLConfigs)",!!
    w $$Test1(sslName)
    
    w !!,"2) $$ListSSLConfigs^%SYS.SECURITY(Client/Server)",!!
    w $$Test2(sslName)
    
  }catch(ex){
    w "Error ", ex.DisplayString(),!
  }

Test1(ssl) {
  d GetSSLConfigList^%SYS.SECURITY1(.SSLConfigs)
  f i=1:1:SSLConfigs return:SSLConfigs(i)=ssl $$$YES
  q $$$NO
}

Test2(ssl) {
  q ''$lf($lfs($$ListSSLConfigs^%SYS.SECURITY("Client")_","_
               $$ListSSLConfigs^%SYS.SECURITY("Server"))
          ,ssl)
}

Working example:

Class dc.test [ Abstract ]
{

/// d ##class(dc.test).Test1()
ClassMethod Test1() [ ProcedureBlock = 0 ]
{
  new active,reactive,info,i
  
  kill info

  set active = 1
  set reactive = 2

  for i="active","reactive" {
    set info(i)= @i
  }

  zw info
}

/// d ##class(dc.test).Test2()
ClassMethod Test2() [ PublicList = (active, reactive) ]
{
  new active, reactive
  kill info

  set active = 1
  set reactive = 2

  for i="active","reactive" {
    set info(i)= @i
  }

  zw info
}

}

^%ZSTART ?

See:

• %SYS.LockQuery
• %SYS.ProcessQuery:VariableByPid()/VariableByJobNumber()
• %SYSTEM.Memory:VariableStats()

Still another option:

Class dc.test Extends %Persistent
{

Property JSONData As list Of %String [ SqlListType = SUBNODE ];

ClassMethod Test()
{
  d ..%KillExtent()
  
  f l=$lb("apple","pear","plum"),$lb({"Name":"Kyle"}.%ToJSON(),{"Name":"Evgeny"}.%ToJSON()) {
    s t=..%New()
    d t.JSONData.InsertList(l)
    d t.%Save()
  }

  zw @$system.Dictionary.comMemberKeyGet($this,$$$cCLASSstorage,$$$nameDefaultStorageNameGet,$$$cSDEFdatalocation)
  
  s rs=##class(%SQL.Statement).%ExecDirect(,"select distinct json_arrayagg(JSONData %foreach(test)) from dc.test_JSONData")
  while rs.%Next() {
    s jsonStr=rs.%GetData(1),
      json=[].%FromJSON(jsonStr)

    w !,jsonStr,", %Size()=",json.%Size(),!
  }
}

}

Result:

USER>d ##class(dc.test).Test()
^dc.testD=2
^dc.testD(1)=$lb("")
^dc.testD(1,"JSONData")=3
^dc.testD(1,"JSONData",1)="apple"
^dc.testD(1,"JSONData",2)="pear"
^dc.testD(1,"JSONData",3)="plum"
^dc.testD(2)=$lb("")
^dc.testD(2,"JSONData")=2
^dc.testD(2,"JSONData",1)="{""Name"":""Kyle""}"
^dc.testD(2,"JSONData",2)="{""Name"":""Evgeny""}"
 
["apple","pear","plum"], %Size()=3
 
[{"Name":"Kyle"},{"Name":"Evgeny"}], %Size()=2

Doc:

• SqlListType
• JSON_ARRAYAGG

See zenConvertType() [///Converts a typed value returned from the server to an appropriate JS type] from zenutils.js.

Try this:

<script src="zenutils.js"></script>

<script language="javascript">
function isItActuallyFalse() {

var bool = zenConvertType('BOOLEAN',#server(..giveMeAFalse())#);

...
}

</script>

<script language="cache" method="giveMeAFalse" arguments="" returntype="%Boolean" procedureblock='1'>return $$$NO</script>

or

var bool = zenBool(#server(..giveMeAFalse())#);
...
<script language="cache" method="giveMeAFalse" arguments="" returntype="%Boolean" procedureblock='1'>return "false"</script>

s tags=$lb("a","b","c"),
  str="c,a1,d,b,f"
   
s l=$lfs(str),ptr=0
while $listnext(tags,ptr,tag) {
  w:$lf(l,tag) tag,!
}

b
c

use %VarString

$tr(str,",",$c(9))
or
$replace(str,",",$c(9))

Once upon a time promised to make Server-Side JavaScript alongside with Caché ObjectScript and Caché Basic:

• JavaScript: Not Just a Client-side Language
  Tuesday, 10:15 AM
  Technical level: Advanced
  Mobile and browser-based applications frequently use JavaScript for their user interfaces. We are working towards implementing JavaScript as one of our server-side scripting languages, thereby allowing developers to use it throughout their applications. In this session we will demonstrate our progress to date.
  Keywords: Mastering Mobile, Caché, Ensemble, concurrent
• Server-Side JavaScript
  Monday, 4:00 PM – 4:45 PM, FLW Ballroom H
  Wednesday, 11:00 AM – 11:45 AM, FLW Ballroom H
  Presenter: Steve LeBlanc
  Task: Use JavaScript to define business logic for applications based on InterSystems’ technology
  Approach: Leverage InterSystems’ new support for server-side JavaScript
  Tags: JavaScript

I found a JS Runtime Shell that uses Node.JS & esprima:

SAMPLES>d ##class(%CPT.JS.Runtime.Shell).Run()
 
JRS> ?
 
.L CLASS   - load javascript methods from CLASS into JS global namespace
.LV var,.. - load the given COS public vars into JS global namespace
 
.S FUNC  - list the source of the method which implements function FUNC
           - FUNC must be in the global namespace
           - the whole implementing method is shown, even for an inner function
           - this will also work for non-javascript methods
.M       - list MAC code from latest compilation
.I       - list INT code from latest compilation
.T       - show latest tree
 
.G       - list global symbols
 
.N CODE  - execute JS on node.js
.N       - execute the last-entered line of JS on node.js
 
.CONFIG ... - passed to %CPT.CalloutShell 'CONFIG' command
 
.SET ... - passed to %CPT.CalloutShell 'SET' command
.CLEAR ... - passed to %CPT.CalloutShell 'CLEAR' command
.SHOW ... - passed to %CPT.CalloutShell 'SHOW' command
 
!COS     - execute a line of COS
 
Anything else is interpreted as JS. :-
* if preceded by "=" it must be a single function definition
* otherwise it can be either a single expression or a sequence
  of statements separated by ";"s
 
Either way it will be compiled into a function body and :-
* if preceded by "==" it is stored as a JS global with the new function's name
* otherwise it will just be executed
 
\n can be used to represent a newline.
 
You can also take input from a file :-
 <FILE    - read JS from FILE and compile+execute it
 <=FILE   - read JS from FILE and compile+store it
 
The result of the execution is shown and also stored in global variable '_'.
 
For a global variable, set it without using 'var' (this will be fixed)


JRS> .N var obj = { name: "John", age: 30, city: "New York" }; JSON.stringify(obj);
{result: "{""name"":""John"",""age"":30,""city"":""New York""}"}

JRS> .N Math.random()
{result: .5670654247514904}

JRS> .N var fruits = ["Banana", "Orange", "Apple", "Mango"]; fruits.sort();
{result: ["Apple", "Banana", "Mango", "Orange", 1: "Apple", 2: "Banana", 3: "Mango", 4: "Orange"]}

JRS> q
 
SAMPLES>