/// Generate docs
Class Utils.Doc
{

/// Generate Docs Tables
/// w $system.Status.DisplayError(##class(Utils.Doc).generate(,"defaultSettings"))
/// w $system.Status.DisplayError(##class(Utils.Doc).generate(,"productionClasses"))
/// w $system.Status.DisplayError(##class(Utils.Doc).generate(,"productionSystemClasses"))
/// w $system.Status.DisplayError(##class(Utils.Doc).generate(,"productionSystemClassesSettings"))
/// w $system.Status.DisplayError(##class(Utils.Doc).generate(,"productionClassesSettings"))
/// w $system.Status.DisplayError(##class(Utils.Doc).generate(,"productionItemsSettingsCall"))
/// w $system.Status.DisplayError(##class(Utils.Doc).generate(,"productionItems"))
/// w $system.Status.DisplayError(##class(Utils.Doc).generate(,"modelClasses"))
/// w $system.Status.DisplayError(##class(Utils.Doc).generate(,"modelPropeties"))
ClassMethod generate(filename As %String = {##class(%File).TempFilename("xlsx")}, query As %String, args...) As %Status
{
    #dim sc As %Status = $$$OK
    #dim stream As %Stream.TmpCharacter = ##class(%Stream.TmpCharacter).%New()
    
    set sql = ..getSQL(query)
    set sc = ##class(util.XLSX).generateStreamFromSQL(.stream, sql, args...)
    quit:$$$ISERR(sc) sc
    
    set file = ##class(%FileCharacterStream).%New()
    set:$p(filename,".",*)'="xlsx" filename = filename _".xlsx"
    set file.Filename = filename
    
    set sc = file.CopyFrom(.stream)
    quit:$$$ISERR(sc)
    
    set sc = file.%Save()
    quit sc
}

ClassMethod getSQL(name) As %String
{
    #dim sc As %Status = $$$OK
    
    set class = $case($l(name, ":"), 2:$p(name, ":"), :$classname())
    set queryName = $p(name, ":", *)
    
    if ##class(%Dictionary.QueryDefinition).IDKEYExists(class, queryName) {
        set query = ##class(%Dictionary.QueryDefinition).IDKEYOpen(class, queryName,,.sc)
        throw:$$$ISERR(sc) ##class(%Exception.StatusException).CreateFromStatus(sc)
        set sql = query.SqlQuery
    } elseif ##class(%Dictionary.XDataDefinition).IDKEYExists(class, queryName) {
        #dim stream As %Stream.Object = ##class(isc.util.XmlUtils).getClassXData(class, queryName)
        set sql = stream.Read($$$MaxLocalLength)
    } else {
        throw ##class(%Exception.StatusException).CreateFromStatus($$$ERROR($$$GeneralError, $$$FormatText("Class %1 does not have Query or XData with name %2", class, queryName)))
    }
    
    set:(removeNL = $$$YES) sql = $replace(sql, $$$NL, " ")
    return sql
}

/// Generic settings for all Interoperability BH
Query defaultSettings() As %Query
{
SELECT
  prop.name Setting,
  TRIM('"' FROM MAX(prop.InitialExpression)) "Default",
  LIST(prop.parent) Classes,
  MAX(prop.Description) Descrition
FROM %Dictionary.PropertyDefinition prop
  JOIN %Dictionary.CompiledParameter par ON par.parent = prop.parent AND par.Name = 'SETTINGS'
  JOIN %Dictionary.CompiledClass cls ON prop.parent = cls.Name
WHERE (cls.Super LIKE '%Ens.Host%' OR cls.Name = 'Ens.Host' OR cls.Name = 'Ens.BusinessProcessBPL') AND
      par."_Default" LIKE '%' || prop.Name || '%'
GROUP BY prop.Name
ORDER BY 1
}

/// Production BHs
Query productionClasses() As %Query
{
SELECT
  Name Class,
  Description Descrition
FROM %Dictionary.CompiledClass cls
WHERE Name LIKE 'production.%'
      AND Super In ('Ens.BusinessProcessBPL', 'Ens.BusinessService', 'Ens.BusinessOperation', 'Ens.BusinessProcess')
ORDER BY 1
}

/// System BHs
Query productionSystemClasses() As %Query
{
SELECT
  Name Class,
  Description Descrition
FROM %Dictionary.CompiledClass cls
WHERE Name In ('util.SQLInboundAdapter', 'EnsLib.SQL.InboundAdapter', 'EnsLib.JavaGateway.Service', 'EnsLib.Workflow.Operation', 'Ens.InboundAdapter')
ORDER BY 1
}

/// System settings for BHs
Query productionSystemClassesSettings() As %Query
{
SELECT
  prop.parent Class,
  prop.name Setting,
  TRIM('"' FROM prop.InitialExpression) "Default",
  prop.Description Descrition
FROM %Dictionary.PropertyDefinition prop
  JOIN %Dictionary.CompiledParameter par ON par.parent = prop.parent AND par.Name = 'SETTINGS'
  JOIN %Dictionary.CompiledClass cls ON prop.parent = cls.Name
WHERE cls.Name IN ('util.SQLInboundAdapter', 'EnsLib.SQL.InboundAdapter', 'EnsLib.JavaGateway.Service', 'EnsLib.Workflow.Operation', 'Ens.InboundAdapter')  AND
      par."_Default" LIKE '%' || prop.Name || '%'
ORDER BY 1,2
}

/// BHs Settings
Query productionClassesSettings(production) As %Query
{
SELECT
  prop.parent Class,
  prop.name Setting,
  TRIM('"' FROM prop.InitialExpression) "Default",
  prop.Description Descrition
FROM %Dictionary.PropertyDefinition prop
  JOIN %Dictionary.CompiledParameter par ON par.parent = prop.parent AND par.Name = 'SETTINGS'
  JOIN %Dictionary.CompiledClass cls ON prop.parent = cls.Name
WHERE cls.Name LIKE :production || '.%' and
      par."_Default" LIKE '%' || prop.Name || '%'
ORDER BY 1,2
}

/// Production BH
Query productionItems(production) As %Query
{
SELECT
  Name Элемент,
  ClassName Class
  /*Comment Comment*/
FROM Ens_Config.Item
WHERE Production = :production
}

/// Get settings for production
Query productionItemsSettingsCall(production) As %Query
{
SELECT *
FROM util.productionItemsSettings(:production)
}

/// Get settings for production
Query productionItemsSettings(production As %String) As %Query(CONTAINID = 0, ROWSPEC = "Элемент:%String,Setting:%String,Цель:%String,Значение:%String") [ SqlName = productionItemsSettings, SqlProc ]
{
}

ClassMethod productionItemsSettingsExecute(ByRef qHandle As %Binary, production As %String) As %Status
{
    set obj = ##class(Ens.Config.Production).%OpenId(production,,.sc)
    quit:$$$ISERR(sc) sc
    do ..clearProductionItems(.obj)
    set qHandle("production") = obj
    set qHandle("item") = 1
    set qHandle("itemCount") = qHandle("production").Items.Count()
    
    set qHandle("setting") = 1
    set qHandle("settingCount") = qHandle("production").Items.GetAt(qHandle("item")).Settings.Count()
    quit sc
}

ClassMethod productionItemsSettingsFetch(ByRef qHandle As %Binary, ByRef Row As %List, ByRef AtEnd As %Integer = 0) As %Status [ PlaceAfter = productionItemsSettingsExecute ]
{
    #dim sc As %Status = $$$OK
    #dim item As Ens.Config.Item = qHandle("production").Items.GetAt(qHandle("item"))
    #dim setting As Ens.Config.Setting = item.Settings.GetAt(qHandle("setting"))

    set AtEnd = 0
    set Row = $lb(item.Name, setting.Name, setting.Target, setting.Value)
    
    if qHandle("setting")<qHandle("settingCount") {
        set qHandle("setting") = qHandle("setting") + 1
    } else {
        if qHandle("item")<qHandle("itemCount") {
            set qHandle("item") = qHandle("item") + 1
            set qHandle("setting") = 1
            set qHandle("settingCount") = qHandle("production").Items.GetAt(qHandle("item")).Settings.Count()
        } else {
            set AtEnd = 1
        }
    }
    
    quit sc
}

/// Remove setting-less hosts
ClassMethod clearProductionItems(ByRef production As Ens.Config.Production)
{
    #dim item As Ens.Config.Item
    for i = production.Items.Count():-1:1 {
        set item = production.Items.GetAt(i)
        do:item.Settings.Count()=0 production.Items.RemoveAt(i)
    }
}

ClassMethod productionItemsSettingsClose(ByRef qHandle As %Binary) As %Status [ PlaceAfter = productionItemsSettingsFetch ]
{
    kill qHandle
    quit $$$OK
}

/// Data model
Query modelClasses() As %Query
{
SELECT
  Name Class,
  Description Descrition
FROM %Dictionary.ClassDefinition
WHERE Name LIKE 'model.%' AND GeneratedBy IS NULL -- AND Name NOT LIKE 'model.ref.%'
}

/// Data model properties
Query modelPropeties() As %Query
{
SELECT
  cls.Name Class,
  prop.Name Свойство,
  prop.Type Тип,
  prop.Description Descrition
FROM %Dictionary.ClassDefinition cls
  JOIN %Dictionary.PropertyDefinition prop ON cls.Name = prop.parent
WHERE cls.Name LIKE 'model.%' AND cls.Name NOT LIKE 'model.ref.%'
}

}