Replacing character groups

Question

Question

Eduard Lebedyuk · Sep 14, 2019

#Code Snippet #ObjectScript #Caché #InterSystems IRIS

What's the best way to replace character groups?

I want not to remove character groups as $zstrip does but to replace them with whitespaces.

$translate needs explicit character list.

Effectively I want to remove any characters besides letters, numbers and a small (known) subset of punctuation characters, replacing everything else with whitespaces.

Discussion (6)1

Log in or sign up to continue

Julius Kavay · Sep 14, 2019

A little bit $translate(), a little bit of $zstrip() and the job is done (in the example below, I want to keep parenthesis)

set str="abcd(123)/,op(56)*&^%$987ABC"

write $tr(str,$zstrip(str,"*AN","()"),$j("",$l(str)))
what to keep generell ------^^^
what to keep extra --------------^^

2 0

score 0 · Answer 1 · 2019-09-14T17:35:48-04:00

By the way, he above works for unicode chars too, unless your pattern match table is outdated ;-))
Another solution is to use an loop and RegEx:


set str="abcd(123)/,op(56)*&^%$987ABC", i=0
set remove="[:punct:]|[:symbol:]"
set keep = "()"

while $locate(str,remove,i,i,c) { set:keep'[c $e(str,i-1)=" " }

score 0 · Answer 2 · 2019-09-14T04:54:05-04:00

Eduard Lebedyuk · Sep 14, 2019

I've been thinking about it but I think there are more letter characters. Unicode is a big place.

0 0

score 0 · Answer 3 · 2019-09-14T04:42:58-04:00

Hi Ed!

This is $Translate again )

Assume you need all the ASCII codes from 33 to 126 - letters, numbers, punctuation.

So:

classmethod onlygood(str) as %String

{

for i=0:1:255 set $E(all,i)=$C(i)

for i=33:1:126 set $E(good,i)=$C(i)

// adding spaces for "no good" symbols

set good=$J("",34)_good_$J("",129)

return $tr(str,all,good)

}

score 2 · Answer 4 · 2019-09-14T07:18:58-04:00

a solution with NO $TRANSLATE

set str="aN d.ef123$eR=xx?,yWz" for i=1:1:$l(str) s:$e(str,i)'?1(1AN,1".",1" ",1",") $e(str,i)=" "

aN d.ef123 eR xx ,yWz

score 2 · Answer 5 · 2019-09-14T13:15:19-04:00

Regexp?

USER> Set str = "abcd(123)/,op(56)*&^%$987ABC"
USER> Write ##class(%Regex.Matcher).%New("[^\w\d()]", str).ReplaceAll(" ")
abcd(123)  op(56)     987ABC

USER> Write ##class(%Regex.Matcher).%New("[^\w\d()]+", str).ReplaceAll(" ")
abcd(123) op(56) 987ABC