How to convert page number to roman numeral in ZEN Report?

I'll try to answer just the conversion question. It looks like someone has asked about roman numerals before here:

https://community.intersystems.com/post/roman-number-converter

However the conclusion was that the referenced article in that question here:

http://docs.intersystems.com/latest/csp/docbook/DocBook.UI.FrameSet.cls?KEY=GVRF_basicfeatures

Doesn't support roman numeral conversion. Now there's a billion ways to do this yourself, and I was inspired by the unary method in one of the answers here, instead of complex loops:

https://stackoverflow.com/questions/12967896/converting-integers-to-roman-numerals-java

So I made something similar for ObjectScript, and it gets the job done in a very simple way. Note that it doesn't use a full Subtractive method for conversion, for that you'll need more cases. The replaces could be structured differently too but I wanted it to be as understandable as possible. Call it in your report however you like.

ClassMethod RomanNumeralConversion(pNum) As %Status {
   set roman = ""
   for x=1:1:pNum {
    set roman = roman_"I"
   }
 
   set roman = $REPLACE(roman,"IIIII", "V")
   set roman = $REPLACE(roman,"IIII","IV")
   set roman = $REPLACE(roman,"VV","X")
   set roman = $REPLACE(roman,"VIV", "IX")
   set roman = $REPLACE(roman,"XXXXX", "L")
   set roman = $REPLACE(roman,"LL", "C")
   set roman = $REPLACE(roman,"LXL", "XC")
   set roman = $REPLACE(roman,"CCCCC", "D")
   set roman = $REPLACE(roman,"CCCC", "CD")
   set roman = $REPLACE(roman,"DD", "M")
   set roman = $REPLACE(roman,"DCD", "CM")
   return roman
}

Page numbering in Roman Numerals

Need add the attribute format to the element <fo:page-sequence>, i.e.

<fo:page-sequence master-reference='blablabla' format ='I' .. >

Possible value format:

• format="1" results in 1 2 3 . .
• format="01" results in 01 02 03
• format="a" results in a b c . .
• format="A" results in A B C. .
• format="i" results in i ii iii iv . .
• format="I" results in I II III IV . .
• more..

Example:

1. Do all the steps according to Zen Report Tutorial
2. Insert the page number into <pagefooter>
   

   <!-- Optional Pagefooter element. Does not apply in HTML output. -->
   <pagefooter>
   <item special="page-number"/>
   </pagefooter>

3. Insert the following code into the class:
   

   ClassMethod ReplaceStream(
     ByRef stream As %Stream.TmpBinary,
     format) [ Private ]
   {
     s tmp=##class(%Stream.TmpBinary).%New()
     while 'stream.AtEnd {
       d tmp.Write($replace(stream.Read($$$MaxLocalLength),"<fo:page-sequence ",$$$FormatText("<fo:page-sequence format=%1 ",$$$quote(format))))
     }
     d stream.CopyFrom(tmp)
   }
   
   /// d ##class(MyApp.ReportDemo).Test()
   ClassMethod Test(format = "1")
   {
     /*
       •0 = XML
       •1 = HTML
       •2 = PDF
       •3 = ToHTML Stylesheet
       •4 = ToXSLFO Stylesheet
       •5 = XSD Schema
       •6 = PrintPS
       •7 = Excel
       •8 = XSLFO
       •9 = ToEXCEL
       •10=xlsx
       •11=TIFF
       •12=pdfprint
       •13=displayxlsx
       •14=fo2pdf
       •15=foandpdf
     */
     
     s xslfo=##class(%Stream.TmpBinary).%New()
   
     s t=..%New()
     d t.GenerateReportToStream(.xslfo,4)
     d ..ReplaceStream(.xslfo,format)
     s t.toxslfostream=xslfo
     d $system.OBJ.DisplayError(t.GenerateReport("c:\temp\test.pdf",2))
   }

4. SAMPLES>d ##class(MyApp.ReportDemo).Test("I")
   or
   SAMPLES>d ##class(MyApp.ReportDemo).Test("01")
   or
   SAMPLES>d ##class(MyApp.ReportDemo).Test("A")

5. open test.pdf. Profit!