How to clone dynamic objects?

Question

Question

Rodrigo Werneck · Dec 15, 2023

How to clone dynamic objects more efficiently than using a serialization/desserialization approach (eg. Set objectB = {}.%FromJSON(objectA.%ToJSON()) ) ?

Why %DynamicObject could not extend %RegisteredObject and its %ConstructClone method (if not inherit it)?

Discussion (4)3

Log in or sign up to continue

Brett Saviano · Dec 18, 2023

@Rodrigo Werneck
I recommend you use an intermediary stream to avoid <MAXSTRING> errors with large JSON objects:

ClassMethod DuplicateDAO(dao As %DynamicAbstractObject) As %DynamicAbstractObject
{
    Set strm = ##class(%Stream.TmpCharacter).%New()
    Do dao.%ToJSON(strm)
    Return ##class(%DynamicAbstractObject).%FromJSON(strm)
}

2 0

score 0 · Answer 1 · 2023-12-15T19:29:56-05:00

A few lines of code and you have your own object cloner

Class DC.ObjCloner [ Abstract ]
{
/// obj: Cache/IRIS or a Dynamic(JSON) Object
/// 
/// For simplicity, JSON-Types null, true, false, etc. are ignored
ClassMethod Clone(obj)
{
    if $isobject(obj) {
        if obj.%IsA("%DynamicAbstractObject") {
            if obj.%IsA("%DynamicObject") { set new={},arr=0 } else { set new=[], arr=1 }
            set iter=obj.%GetIterator()
            while iter.%GetNext(.key,.val) {
                set:$isobject(val) val=..Clone(val)
                do $case(arr, 1:new.%Push(val), :new.%Set(key,val))
            }
            quit new
            
        } else { quit obj.%ConstructClone(1) }
    } else { quit "" }
}
}

score 0 · Answer 2 · 2023-12-16T08:22:53-05:00

@Julius Kavay , nice code.

But the point was "more efficiently than using a serialization/deserialization", with this code it takes more than 4 times as serialization/deserialization.

I think that using serialization/deserialization IS very efficient.

@Rodrigo Werneck , are you having performance issues? What makes you think serialization/deserialization is inefficient? Did you measure the performance in your use case?

Enrico

score 0 · Answer 3 · 2023-12-18T06:31:33-05:00

@Enrico Parisi, I did no measures. I just thought that doing like @Julius Kavay suggested should be more direct and more efficient. Perhaps his code takes more time because it runs in ObjectScript semi-interpreted code while internal methods like %ToJSON and %FromJSON seems to be in external C compiled code ($zu(210)?).

Thank you both,