$CASE For Long Stories

Question

Question

Evgeny Shvarov · Jun 5, 2018

Hi, Community!

$CASE is a fine syntax sugar for "Ifs" with one-line/one-word expressions, like in docs:

SET daynum=$ZDATE($HOROLOG,10)
  WRITE $CASE(daynum,
              1:"Monday",2:"Tuesday",3:"Wednesday",
              4:"Thursday",5:"Friday",
              6:"Saturday",0:"Sunday",:"entry error")

But if my expression for a current case is a multi-line business logic? Can I use "{}" somehow or better go with "IF" instead?

Discussion (13)2

Log in or sign up to continue

Gilberto Junior · Jun 5, 2018

Hi in this case I have already used a function that returns a string, with this I came to a utility very similar to the switch case of other languages Sorry for the possible inconsistency in the response, it was translated by google translator

Example:

Class Case.Teste Extends %SerialObject
{

ClassMethod Teste(pReq As %Integer)
{
WRITE $CASE(pReq,
1:..Oi(),2:..Tchau(),: ..GOKU())
}

ClassMethod Oi() As %String
{
Quit "OI sou do Brasil"
}

ClassMethod Tchau() As %String
{
Quit "Um abraço"
}

ClassMethod GOKU() As %String
{
Quit "Oi Eu sou o GOKU"
}

Storage Default
{
<StreamLocation>^Case.TesteS</StreamLocation>
<Type>%Library.CacheSerialState</Type>
}

}

USER>do ##Class(Case.Teste).Teste(1)
OI sou do Brasil

USER>do ##Class(Case.Teste).Teste(2)
Um abraço

USER>do ##Class(Case.Teste).Teste(3)
Oi Eu sou o GOKU

USER>

2 0

score 0 · Answer 1 · 2018-06-05T12:29:04-04:00

Eduard Lebedyuk · Jun 5, 2018

Post Teste method?

0 0

score 0 · Answer 2 · 2018-06-05T13:53:59-04:00

Evgeny Shvarov · Jun 5, 2018

Thanks Gilberto, this is a possible way, thanks.

0 0

score 0 · Answer 3 · 2018-06-05T13:59:00-04:00

Hi, Ed!

Thanks!

I'll elaborate the problem a bit. Here is the $case everybody loves:

write $case(condition, 1:expression1, 2:expression2, expression3)

My problem is that with business logic change the expression1 and expression2 showed the need for multiline logic. And I was looking for something like:

write $case(condition,

1: {

New cool logic for expression 1 with line 1
and line 2


},

2:{

Perfect, better logic for expression2
maybe with 
few lines
more

},

expression3)

score 0 · Answer 4 · 2018-06-06T04:11:35-04:00

Evgeny Shvarov · Jun 6, 2018

Thanks Vitaly!

Really great!

Classmethod Public: is it to be able to call for $$functions in a class?

0 0

score 0 · Answer 5 · 2018-06-05T13:30:49-04:00

Gilberto Junior · Jun 5, 2018

Sorry for copying and pasting

thank you

0 0

score 0 · Answer 6 · 2018-06-05T15:38:47-04:00

Like this:

write $case(condition,
             1:{ 
                 set a="hello " _"world"
                 return a
               }    
             2:"name",
             :"!")

I figured out that the thing I want is close to "closures" ;)

score 1 · Answer 7 · 2018-06-05T15:41:39-04:00

Pinging @Alexander Koblov

Isn't it more like anonymous functions?

Currently not possible. Check @Gilberto Junior solution - it seems the closest to what you want.

score 0 · Answer 8 · 2018-06-05T14:12:38-04:00

Like this?

 write $case(condition,
             1:"hello " _
               "world",
             2:"name",
             :"!")

Hello world is a multiline expression.

score 0 · Answer 9 · 2018-06-06T04:28:40-04:00

Vitaliy Serdtsev · Jun 6, 2018

Yes, this (Classmethod Public) is only necessary for the second example.

0 0

score 0 · Answer 10 · 2018-06-05T10:44:39-04:00

Sean Connelly · Jun 5, 2018

how about...

write $zdate($h,12)

0 0

score 0 · Answer 11 · 2018-06-05T12:23:44-04:00

I'd go with if, but you can also resolve case expression beforehand:

set condition = .... several lines of logic...
write $case(condition, ...)

And condition then can be separaten into several different lines.

I'm against method chaining in general and several functions on one line/step in particular.

Each line should contain one small operation.

score 1 · Answer 12 · 2018-06-06T02:32:35-04:00

Choose to your taste:

Class dc.test [ Abstract ]
{

ClassMethod Public() [ Internal, Private, ProcedureBlock = 0 ]
{
  q
Choice0()
  q "Sunday"
Choice1()
  q "Monday"
Choice2()
  q "Tuesday"
Choice3()
  q "Wednesday"
Choice4()
  q "Thursday"
Choice5()
  q "Friday"
Choice6()
  q "Saturday"
Choice()
  set a="entry " _"error"
  return a
}

/// d ##class(dc.test).Test()
ClassMethod Test()
{
  s daynum=$zd($h,10)

  w "1) ",$case(daynum,
                0:$$Choice0,
                1:$$Choice1,
                2:$$Choice2,
                3:$$Choice3,
                4:$$Choice4,
                5:$$Choice5,
                6:$$Choice6,
                :$$Choice),!

  w "2) ",@("$$Choice"_$case(daynum,
                              0:0,
                              1:1,
                              2:2,
                              3:3,
                              4:4,
                              5:5,
                              6:6,
                              :"")),!

  s daynum="-"
  
  w "3) ",$case(daynum,
                0:"Sunday",
                1:"Monday",
                2:"Tuesday",
                3:"Wednesday",
                4:"Thursday",
                5:"Friday",
                6:"Saturday",
                :$xecute("()"_
                          " set a=""entry "" _""error"""_
                          " return a")),!
}

}