To download that image, you need just a few lines of code

Class Some.Class Extends %RegisteredObject
{
ClassMethod GetImage()
{
	s req=##class(%Net.HttpRequest).%New()
	s req.Server="www.distrelec.de"
	s req.SSLConfiguration="SSL" // use your SSL-Config-Name
	d req.Get("/Web/WebShopImages/landscape_medium/_t/if/sortimentsboxen-1.jpg",1)
	q req.HttpResponse
}
}

So your code is more or less OK, but the rest of the process is ominous

set rsp=##class(Some.Class).GetImage()
zw rsp
rsp=7@%Net.HttpResponse  ; <OREF>
+----------------- general information ---------------
|      oref value: 7
|      class name: %Net.HttpResponse
| reference count: 3
+----------------- attribute values ------------------
|    ContentBoundary = ""
|        ContentInfo = "charset=UTF-8"
|      ContentLength = 17759
|        ContentType = "image/jpeg;charset=UTF-8"
|               Data = "8@%Stream.GlobalCharacter"
|Headers("CACHE-CONTROL") = "max-age=0"
|Headers("CONTENT-LENGTH") = 17759
|Headers("CONTENT-TYPE") = "image/jpeg;charset=UTF-8"
|    Headers("DATE") = "Mon, 14 Nov 2022 10:57:10 GMT"
|    Headers("ETAG") = "a919e895229c7883864aecbfa2717516"
|Headers("LAST-MODIFIED") = "Thu, 01 Jan 1970 00:00:01 GMT"
|Headers("SET-COOKIE") = "visid_incap_2373370=1U8JalxbRJOzRFviQpi05AYfcmMAAAAAQUIPAAAAAADRm"
|Headers("STRICT-TRANSPORT-SECURITY") = "max-age=31536000; includeSubDomains; preload"
|   Headers("X-CDN") = "Imperva"
| Headers("X-IINFO") = "5-19652015-0 0CNN RT(1668423430526 51) q(0 -1 -1 0) r(0 -1)"
|        HttpVersion = "HTTP/1.1"
|       ReasonPhrase = "OK"
|         StatusCode = 200
|         StatusLine = "HTTP/1.1 200 OK"
+-----------------------------------------------------

The sender says, content type is "image/jpeg", which is OK, but charset=UTF-8 is, I think, a problem. A jpeg-image usually starts with (hex) bytes:

FF D8 FF E0 00 10 4A 46 49 46 ...

The HTTP-Response gives us

do rsp.Data.Rewind()
zzdump rsp.Data.Read(10)

3F 3F 3F 10 4A 46 49 46 00 01                           ???.JFIF..

But I'm in no way a web-expert, but it seems to me, Cache tries to decode (according to content-type =image/jpg; charset=UTF-8) the incomming raw (jpeg) data. The first byte, FF, will already give an error (no utf-8 encoded byte can start with FF) and returns an "?" char as a replacement. The next two "?" (hex: 3F) chars are also arised from (inpossible) decoding. Why the same page works, if you try it with Chrome or Firefox: I think, they either ignore the charset=UTF-8 or just show the raw data after the first decoding error.

A small complaint:
- possible word delimiters weren't specified (space, tab, etc.)
- no specification about punctuation marks (allowed or disallowed)
- no specification about empty words (allowed or disallowed) and how to handle them, if allowed

So my question is, are the following examples legal or not:

"O2K. I'1m" --> "I'm OK."
"spac4es are2    1There     ma3ny" --> "There are many spaces."

As I learned the hard way, abstract classes do not have storage implementation, hence no indices either

One of the possible solutions

/// You can change the s:b]"" to an comma if there is always exact one space between the words
/// and remove the ,1) from $lts() if all word are numbered from 1..N with no number missing
ClassMethod WordOrder(s)
{
    s z="" f i=1:1:$l(s," ") s b=$p(s," ",i) s:b]"" $li(z,$zstrip(b,"*ap"))=$zstrip(b,"*n")
    q $lts(z," ",1)
}

This is a working solution and maybe not the shortest

I never had this kind of problem, but a quick and dirty method would be: 1) remove the 'Mount Read-only' flag, 2) run the tune table utility, 3) reenable the 'Mount Read-only flag'.  I hope, you do not have some mean application, waiting for the chance of his life, to get a writable database...

You can it enter via terminal, no question about, but it's a little bit cumbersome

// create the class
s cls=##class(%Dictionary.ClassDefinition).%New()
s cls.ProcedureBlock=1
s cls.Super="%RegisteredObject"
s cls.Name="ObjectScript.RightTriangle"

// add one method
s mth=##class(%Dictionary.MethodDefinition).%New()
s mth.Name="Main"
s mth.Description="Compute area and hypotenuse of a right triangle"
d mth.Implementation.WriteLine($c(9)_"write !,""Compute the area and hypotenuse of a right triangle"",")
d mth.Implementation.Write($c(9,9)_"!,""given the lengths of its two sides.""")
d cls.Methods.Insert(mth)

// add one more method
s mth=##class(%Dictionary.MethodDefinition).%New()
s mth.Name="Area",mth.Description="Area, computed from sides 'a' and 'b'"
s mth.FormalSpec="a,b"
d mth.Implementation.WriteLine($c(9)_"quit a*b/2")
d cls.Methods.Insert(mth)

// save the class (it's NOT compiled!)
w cls.%Save()

As you may see, creating a class via an IDE is simpler... but yes, in an emergency case you can do it also via a console access

The problem has nothing in common with Cache or IRIS, it's an OS setting. If a network drive is not available (for example the target is switched off), Windows waits an half an eternity.

You have to ask your sysadmin or Google, providing your Windows version. The very first hit I found is this but it's somewhat old.

Nice, merely your insert rate is somewhat low. About ten years ago, Cache inserted in proof-of-concept project  112000 rows per second. Seen in this way, the  (708000/20) 35400 are a bit little... 

Assuming, fields which contains commas are quoted ("aaa,bbb,ccc") and (for the simplicity) fields does not contains quotes, then something like this should do the job

ClassMethod CSV(filename)
{
	s old=$system.Process.SetZEOF(1)	// use $zeof instead of error trap
	s result=[]
	o filename:"r":0
	i $t {
		u filename
		while '$zeof {
			read line
			i line]"" do result.%Push(..fields(line)) // ignore empty lines
		}
	}
	c filename
	d $system.Process.SetZEOF(old)
	q result
}

ClassMethod fields(line)
{
	s a="", f=0, row=[]
	f i=1:1:$l(line) {
		s c=$a(line,i)
		i c=44,'f d row.%Push(a) s a="" continue
		i c=34 s f='f continue
		s a=a_$c(c)
	}
	q row
}

A test output:

USER>s res=##class(DC.Help).CSV(fn)

USER>zso res
(0).(0).............: 12162
(0).(1).............: CHAPTER I
(0).(2).............: Certain infectious and parasitic diseases (A00-B99)
(0).(3).............: 003 (A20-A28)
(0).(4).............: Certain zoonotic bacterial diseases
(0).(5).............: A28
(0).(6).............: Other zoonotic bacterial diseases, not elsewhere classified
(0).(7).............: A28
(0).(8).............: Other zoonotic bacterial diseases, not elsewhere classified
(0).(9).............: N
(0).(10)............: N
(0).(11)............: N
(0).(12)............: N
(0).(13)............: N
(0).(14)............:
(0).(15)............:
(0).(16)............:
(0).(17)............:
(0).(18)............:
(0).(19)............:
(0).(20)............:
(0).(21)............:
(0).(22)............:

This is just a hint: your Get() argument should be URL-encoded (colons are not allowed in an URL):

Set tSc=Httprequest.Get($zcvt(HttpURL,"O","URL"))