I.e. you need Callback methods for Studio, Atelier, etc.?

• for Studio: Extending Studio (OnBeforeCompile, OnBeforeClassCompile, OnBeforeAllClassCompile, etc.)
• for Atelier: %Atelier.SourceControl (OnBeforeCompile, OnBeforeClassCompile, OnBeforeAllClassCompile, etc.)

And if so?

Class dc.EmbedObj Extends %SerialObject
{

Property pOID As %ObjectIdentity [ Private ];

Property a As %String;

Property b As %String [ Calculated, SqlComputeCode = {s {*}=##class(dc.EmbedObj).Calcb({pOID})}, SqlComputed ];

ClassMethod Calcb(pOID) As %String
{
  s r=""
  q:pOID="" r

  s $lb(id,cls)=$lfs(pOID,"@")

  s p=$system.OBJ.OpenId(cls,id)
  q:'$IsObject(p) r

  i cls="dc.ContainerObj" {
    s r="b"_p.Foobar
  }elseif cls="dc.blablablaContainerObj" {
    s r="b"_p.qwe
  }
  q r
}
}

Class dc.ContainerObj Extends %Persistent
{

Property Foobar As %String;

Property InnerObj As dc.EmbedObj;

Trigger NewTrigger1 [ Event = INSERT, Foreach = row/object, Time = AFTER ]
{
  n oid
  s oid={%%ID}_"@"_{%%CLASSNAMEQ}
  &sql(update dc.ContainerObj set InnerObj_pOID=:oid where %ID=:{id})
}

/// d ##class(dc.ContainerObj).Test()
ClassMethod Test()
{
  d ..%KillExtent()
  
  s t=..%New()
  s t.Foobar="foobar1"
  s t.InnerObj.a="a1"
  d t.%Save()

  &sql(insert into dc.ContainerObj(Foobar,InnerObj_a) values('foobar2','a2'))
  
  d ##class(%SQL.Statement).%ExecDirect(,"select * from dc.ContainerObj").%Display()
}
}

This not it?

• #Execute
• ##Expression
• ##Function

For serial class, I'm afraid that's not possible because of its nature.
$this, $classname, etc. in the context of EmbedObj don't know anything about ContainerObj.

Use bidirectional Relationship.

Yes, this (Classmethod Public) is only necessary for the second example.

Choose to your taste:

Class dc.test [ Abstract ]
{

ClassMethod Public() [ Internal, Private, ProcedureBlock = 0 ]
{
  q
Choice0()
  q "Sunday"
Choice1()
  q "Monday"
Choice2()
  q "Tuesday"
Choice3()
  q "Wednesday"
Choice4()
  q "Thursday"
Choice5()
  q "Friday"
Choice6()
  q "Saturday"
Choice()
  set a="entry " _"error"
  return a
}

/// d ##class(dc.test).Test()
ClassMethod Test()
{
  s daynum=$zd($h,10)

  w "1) ",$case(daynum,
                0:$$Choice0,
                1:$$Choice1,
                2:$$Choice2,
                3:$$Choice3,
                4:$$Choice4,
                5:$$Choice5,
                6:$$Choice6,
                :$$Choice),!

  w "2) ",@("$$Choice"_$case(daynum,
                              0:0,
                              1:1,
                              2:2,
                              3:3,
                              4:4,
                              5:5,
                              6:6,
                              :"")),!

  s daynum="-"
  
  w "3) ",$case(daynum,
                0:"Sunday",
                1:"Monday",
                2:"Tuesday",
                3:"Wednesday",
                4:"Thursday",
                5:"Friday",
                6:"Saturday",
                :$xecute("()"_
                          " set a=""entry "" _""error"""_
                          " return a")),!
}

}

Here is my solution, which has a number of advantages:

1. there are no restrictions to the order of ID
2. you can search in queries for the entire timestamp or for parts of it
3. standard, reliable and proven Caché features are used
4. this works very, very fast.

See my article for details: Indexing of non-atomic attributes

Class dc.TSOrder Extends (%Persistent, %Populate)
{

Index Extent [ Extent, Type = bitmap ];

Index iSmartTS On (TS(KEYS), TS(ELEMENTS));

Index iTS On TS;

Property TS As %TimeStamp(MAXVAL = "2016-07-31 23:59:59.999999", MINVAL = "2016-07-01 00:00:00.000000");

Property Data As %String(MAXLEN = 200, MINLEN = 100);

ClassMethod TSBuildValueArray(
  value,
  ByRef array) As %Status
{
  i value="" {
    s array(0)=value
  }else{
    s date=$p(value," ",1),
    time=$p(value," ",2),
    array("date")=date,
    array("time")=time,
    array("ddhh")=$p(date,"-",3)_"-"_$p(time,":",1)
  }
  q $$$OK
}

/// d ##class(dc.TSOrder).Fill()
ClassMethod Fill(N = {30e6})
{
  d ..%KillExtent(), ..Populate(N), $system.SQL.TuneTable($classname(),$$$YES), $system.OBJ.Compile($classname(),"cu-d")
}

}

Results from SMP:

select distinct null from dc.TSOrder where TS between {ts '2016-07-01 00:00:00.00000'} AND {ts '2016-07-01 23:59:59.999999'}

Performance: 2.339 seconds  2109755 global references 14768692 lines executed
(the number of selected records is 968476, used the normal index)

select distinct null from dc.TSOrder where for some %element(TS) (%key='date' and %value = '2016-07-01')

Performance: 2.269 seconds  1936962 global references 15496098 lines executed
(the number of selected records is 968476, used the "smart" index)

select distinct null from dc.TSOrder where for some %element(TS) (%key='ddhh' and %value = '01-13')

Performance: 0.096 seconds  80488 global references 644270 lines executed
(the number of selected records is 40239, used the "smart" index)

SYS.DataCheck.GlobalReference:IsValid

You can see the code examples and coding style in the sources of namespaces '%SYS' and/or 'SAMPLES'.
But keep in mind that the style of classes written a long time ago differs significantly from style of classes written relatively recently, ex. [$ZT vs try/catch] or [%ResultSet vs %SQL.Statement]

For self - education is the best - documentation, for example:

• Introduction to Caché
• Caché Programming Orientation Guide
• ObjectScript Tutorial
• Caché QuickStart Tutorial
• General System Limits
• Identifier Length Considerations
• and etc.

Localization in Caché DBMS

Simple example:

1. Class dc.test Extends %ZEN.Component.page
   {
   
   Parameter DOMAIN = "DCTEST";
   
   XData Contents [ XMLNamespace = "http://www.intersystems.com/zen" ]
   {
   <page xmlns="http://www.intersystems.com/zen">
     <radioSet id="lng"
       label="Текущий язык"
       layout="vertical"
       displayList="Португальский,Русский"
       valueList="pt-br,ru"
       value="ru"
       onchange="zenPage.changeLang(zenThis.value);"
     />
     <form>
       <text label="Описание" required="true" requiredMessage="обязательно." />
       <submit caption="Сохранить"/>
     </form>
   </page>
   }
   
   /// User clicked to change preferred language.
   ClientMethod changeLang(lng) [ Language = javascript ]
   {
     var ok = this.SrvChangeLang(lng);
     self.document.location.reload();
   }
   
   /// Change preferred language for this session and page
   ClassMethod SrvChangeLang(lng) As %Boolean [ ZenMethod ]
   {
     s %session.Language=lng
     s %response.Language=lng
     q $$$YES
   }
   
   Method %OnAfterCreatePage() As %Status
   {
     d ..%SetValueById("lng",%session.Language)
     Quit $$$OK
   }
   
   }

2. USER>d ##class(%MessageDictionary).ExportDomainList("messages_ru.xml","DCTEST","ru")
   
   Result (messages_ru.xml):
   
   <?xml version="1.0" encoding="UTF-8"?>
   <MsgFile Language="ru">
      <MsgDomain Domain="DCTEST">
         <Message Id="358179803">Текущий язык</Message>
         <Message Id="1805419696">Португальский,Русский</Message>
         <Message Id="2153752096">Описание</Message>
         <Message Id="2835101332">обязательно.</Message>
         <Message Id="3683485237">Сохранить</Message>
      </MsgDomain>
   </MsgFile>
   

3. messages_pt-br.xml:
   
   <?xml version="1.0" encoding="UTF-8"?>
   <MsgFile Language="pt-br">
      <MsgDomain Domain="DCTEST">
         <Message Id="358179803">Idioma atual</Message>
         <Message Id="1805419696">Português,Russo</Message>
         <Message Id="2153752096">Descrição</Message>
         <Message Id="2835101332">é obrigatório.</Message>
         <Message Id="3683485237">Salvar</Message>
      </MsgDomain>
   </MsgFile>
   
   USER>d ##class(%MessageDictionary).Import("messages_pt-br.xml")

4. Profit!