Just to add - I'm successfully using both source control and non-source control extensions (all using the %Studio.Extension framework) from VSCode. If there are specific issues you see, I'd be curious to hear about them.

This is a little messy and I'm going to report part of the answer as a bug internally. But regardless, here's one way to make it work - in short, have all of the things that could be listed as a recipient extend a common parent class, and in that class override %JSONNew to detect which type it is.

Class DC.Demo.Container Extends (%RegisteredObject, %JSON.Adaptor)
{
Property recipient As DC.Demo.Recipient;
ClassMethod Demo()
{
    for json = {"recipient":{"dob":"2021-06-10"}}, {"recipient":{"reference":"foo"}} {
        set inst = ..%New()
        do inst.%JSONImport(json)
        write !,json.%ToJSON(),!,$classname(inst.recipient),!
    }
}
}

Class DC.Demo.Recipient Extends (%RegisteredObject, %JSON.Adaptor)
{
/// Get an instance of an JSON enabled class.<br><br>
/// 
/// You may override this method to do custom processing (such as initializing
/// the object instance) before returning an instance of this class.
/// However, this method should not be called directly from user code.<br>
/// Arguments:<br>
///     dynamicObject is the dynamic object with thee values to be assigned to the new object.<br>
///     containerOref is the containing object instance when called from JSONImport.
ClassMethod %JSONNew(dynamicObject As %DynamicObject, containerOref As %RegisteredObject = "") As %RegisteredObject
{
    // This is weird: shouldn't need to reference .recipient here
    if dynamicObject.recipient.%IsDefined("dob") {
        quit ##class(DC.Demo.Patient).%New()
    } elseif dynamicObject.recipient.%IsDefined("reference") {
        quit ##class(DC.Demo.Reference).%New()
    } else {
        quit ..%New()
    }
}
}

Class DC.Demo.Reference Extends DC.Demo.Recipient
{
Property reference As %String;
}

Class DC.Demo.Patient Extends DC.Demo.Recipient
{
Property dob As %Date;
}

Output is:

 d ##class(DC.Demo.Container).Demo()
{"recipient":{"dob":"2021-06-10"}}
DC.Demo.Patient
{"recipient":{"reference":"foo"}}
DC.Demo.Reference

Only problem is, %JSONNew (as advertised in class reference documentation) should get the %DynamicObject representing the object itself, not the parent %DynamicObject. This would only really work if each type is used in exactly one context like this, which seems unlikely.

I recently wrote up an example here: https://community.intersystems.com/post/making-most-query

Perhaps pass the object ID into something like:

Query GetInfo(refId As %String) As %SQLQuery(CONTAINID = 1, ROWSPEC = "IdList:%String,IdProcess:%String,Duration:%String")
{
    SELECT list.IdList, list.IdProcess, list.Duration
    FROM Kurro.MyClass list
    JOIN Kurro.MyClass ref on ref.ID = :refId
    AND ref.KeyProcess = list.KeyProcess
    AND ref.CodeSpecialist = list.CodeSpecialist
    AND ref.CodeProvider = list.CodeProvider
    AND ref.CodeCenter = list.CodeCenter
    AND ref.Date = list.Date
}

Worldwide Response Center (WRC)

For Immediate Response 

Phone:
+1-617-621-0700
+44 (0) 844 854 2917
0800615658 (NZ Toll Free)
1800 628 181 (Aus Toll Free)

Email:
support@intersystems.com

Online:
WRC Direct
Email support@intersystems.com for a login.

@Tani Frankel this is a nice solution! I'd still like to see this there automatically somehow though.

I think I've seen this before when IRIS responds with a login page due to credentials being passed to the SOAP call incorrectly. https://community.intersystems.com/post/example-connecting-cach%C3%A9-w… has an example of the expected headers, though in PHP (likely not your language of choice here).

With $zf(-100) the command and its individual flags are separate arguments to the function rather than being concatenated in one string - I'd recommend trying something more like:

set sc = $ZF(-100,"/STDIN="""_imageFile_""" /STDOUT="""_tempFile_"""","magick","fd:0","-resize","640x480","fd:1")

For more details see https://docs.intersystems.com/irislatest/csp/docbook/DocBook.UI.Page.cl…

If I understand what you're asking correctly, this is a really great question that hits on a kind of tricky aspect of ObjectScript/persistence. In short, if you already have a persistent object in memory (with a variable, say thingOne, assigned to it), and you open the same ID again and assign another variable to it (say, thingTwo), the OREF will be reused - both variables will point to the same object, and that one in-memory instance of the object can be modified via either variable. This can easily lead to some confusing scenarios.

Here's a quick demonstration of the fact:

Class DC.Demo.OREFOIDDemo Extends %Persistent
{

Property Foo As %String;

ClassMethod RunDemo()
{
    Do ..%KillExtent()
    
    Set thingOne = ..%New()
    Set thingOne.Foo = "Bar"
    Do thingOne.%Save()
    
    Set thingTwo = ..%OpenId(thingOne.%Id())
    Set thingTwo.Foo = "Baz"
    
    Write !,"thingOne = ",thingOne
    Write !,"thingTwo = ",thingTwo
    Write !,"thingOne.Foo = ",thingOne.Foo
    Write !,"thingTwo.Foo = ",thingTwo.Foo
}

}

Running the method produces the output:

Do ##class(DC.Demo.OREFOIDDemo).RunDemo()

thingOne = 18@DC.Demo.OREFOIDDemo
thingTwo = 18@DC.Demo.OREFOIDDemo
thingOne.Foo = Baz
thingTwo.Foo = Baz

It may surprise you that thingOne.Foo has also been set to "Baz" - but as you can see, thingOne and thingTwo reference the same object.

Note that if for some reason I wanted to know the current persisted value of thingOne.Foo, I could use:

thingOne.FooGetStored(thingOne.%Id())

Is forwarding cconsole.log an option? There should be a 0-severity message there like:

05/15/19-13:52:53:824 (2144) 0 cleaned dead job, pid: 4012, jobid 0x00010013