"IF THEN - $SELECT - $CASE" - What is the best way?

If you use the IF style, I suggest you also consider using the ELSEIF clause. See doc here.

 set caseSwitch = 1

 if (caseSwitch = 1)
 {
   write "Case 1"
 }
 elseif (caseSwitch = 2)
 { 
   write "Case 2"
 }
 else
 {
    write "Default case"
 }

http://localhost:57772/csp/docbook/DocBook.UI.Page.cls?KEY=RCOS_fselect

http://localhost:57772/csp/docbook/DocBook.UI.Page.cls?KEY=RCOS_fcase

Hi,

I won't claim this is an answer, because it's not quite the same and people may object to the structure, but here is one solution that is used quite a lot in code I look after. Basically, a subroutine is called and then tests are done and a Quit is used to drop out when a match is found. Often used for validation, something like this that returns a result in the zER variable:

V1 ; Validate ORGC
   S ORG=zORG D WC2^hZUTV I zER'="" Q
   I IPACC<9,'$D(^hIW(WAID)) S zER="No details set up for ward" Q
   D WARDON^hILO1 I LOCK S zER="Ward in use" Q

VQ2 Q

Apologies for the old-fashioned code! However, you can see each test can be quite complex and using lots of variables, but it is easy to understand as long as you expect the structure to work that way.

This is very similar to the "clean code" solution of making the whole thing into a function that returns a value:

ClassMethod Main(val1 As %String, val2 As %String)
 {
  write ..MyOutput(val1,val2)
 }

ClassMethod MyOutput(val1 As %String, val2 As %String) As %String
 {
  if val1 = 1 return "case 1"
  if val1 = 2, val2="*" return "case 2"
  return "default match"
 }

Of course there are probably as many answers as there are Cache programmers!  :-)

You might want to restructure your multiple conditions per $case in a somewhat unusual fashion like this

Class User.FunWithCASE
{
ClassMethod CaseDemo(pNum as %Integer, pBoole as %Boolean = 0, pStr as %String) as %String
{
    return $case(1,  /* whatever is true first */
                 (pNum>100)   :"num gt than 100",
                 ((pBoole=1) && (pStr["Green Bay Packers")) : "True Superbowl Champion found!!!!",
                 ((pNum<=2) || ($length(pStr)>40))          : "num lt 2 or a looong string",
                                                            : ..NestedCase(pNum,pBoole,pStr))    
}

ClassMethod NestedCase(pNum as %Integer, pBoole as %Boolean = 0, pStr as %String) as %String
{
        return $case(1,  /* whatever is true first */
                 (pBoole=0)               : "not true ",
                 (pStr["Miami Dolphins")  : "Whatever",
                 ($e(pStr,*-4,*)="kees")  : "Mon or Yan found",
                                          : "Nothing rhymed in here")_" (nested)"
}

ClassMethod RunTest()
{
    for tNum=1,2,10,101
    {
        for tBoole = 0,1
        {
            set tList= $lb( "Green Bay Packers",
                            "MiamiDolphins",
                            "New York Yankees",
                            "Maxwell's Silver Hammer",
                             $tr($j(" ",41)," ","*")
                           )
            set tPos=0,tStr=""
            while ($listnext(tList,tPos,tStr))                 
            {
                write !,"CaseDemo("_tNum_","_$case(tBoole,1:"true",:"false")_","_$$$quote(tStr)_")"
                       ,?40,..CaseDemo(tNum,tBoole,tStr)
            } 
        }
    }
}
}

Obviously, a complex condition cannot produce simple code. I do this in that way:

 set val1 = 1
 set val2 = 2
 set val3 = 3

 w $SELECT(
     (val1>=3)&&(val1<=9):
     $SELECT(
        val2=0:"Condition 1",
        val2>0:"Condition 2"),
        val2=1:$SELECT(
                val3<3:"Condition 3",
                     1:"Condition default 1"
              ),
       val2'=1:$SELECT(
                 (val2>1) && (val2<9):"Condition 4",
                                    1:"Condition default 2"
               )
    ),!

It's more clear and readable.