How do I get the name of the OS user used by the IRIS superserver?

Question

Question

Evan Gabhart · Mar 13

Is there a way in ObjectScript to return the OS user of the superserver? I know %SYS.ProcessQuery can find this for a given process but is there a clean way independent of a specific process ID I can find the OS user used for background jobs?

For IRIS this is usually irisusr and Caché this is usually cacheusr but may vary based on installation and upgrade history of an instance. I would find it very useful to determine programmatically if a process is running as this particular user when the username may vary.

Discussion (12)3

Log in or sign up to continue

Alice Shrestha · Mar 16

Not sure what the use case here is, but you could also just run a SQL query on the process query table as well:

&SQL(SELECT OSUserName Into :OSUserName FROM %SYS.ProcessQuery where JobType = 24)

0 0

score 2 · Answer 1 · 2025-03-13T18:06:07-04:00

Try this method

Class DC.Util Extends %RegisteredObject
{

/// Return: the OS username for this Cache/IRIS instance
/// 	
/// First, get the port of the superserver
/// then search, which job owns that port
/// then return the OSUsername for that job
/// 
ClassMethod OSUsername()
{
	new $namespace
	set $namespace="%SYS"
	
	if ##Class(Config.Startup).Get(.par),$d(par("DefaultPort"),port) {
		set job="", pattern=".e1""|TCP|"_port_"*"".e"
		for  set job=$zj(job) quit:$v(-1,job)?@pattern||(job="")
		
		if job {
			set proc=##class(%SYS.ProcessQuery).%OpenId(job)
			ret:proc proc.OSUserName
		}
	}
	ret ""
}

}

A note:
- I know of a $zu(...) function which works and returns the superserver port but $zu() functions are deprecated/discouraged
- and this one is not in the replacement list - why?

score 4 · Answer 2 · 2025-03-13T18:35:11-04:00

Alice Shrestha · Mar 13

Maybe something like this,

$SYSTEM.Process.UserName($ZJ(""))

4 0

score 0 · Answer 3 · 2025-03-14T07:17:40-04:00

This looks like simplicity itself, thank you Alice!

However, I am not able to find any documentation on $ZJob accepting arguments (https://docs.intersystems.com/iris20243/csp/docbook/Doc.View.cls?KEY=RCO...) - do you have a reference for how to use this?

score 0 · Answer 4 · 2025-03-14T10:55:22-04:00

I found no direct documentation but got some information from the method documentation of the NextProcess class method in %SYS.ProcessQuery:

https://docs.intersystems.com/iris20243/csp/documatic/%25CSP.Documatic.c...

So, it seems passing an argument works like $order on the list of running processes with the caveat a halted process is treated like $zjob("") and returns the first process id in the list. I think this will do the trick, thanks Alice!

score 0 · Answer 5 · 2025-03-14T11:15:07-04:00

do we know that the "1st process" is? Is there a specific daemon which is always considered first? This only would list PIDs running iris (not all PIDs on the OS), correct?

score 1 · Answer 6 · 2025-03-14T11:54:56-04:00

Thank you for asking this, Ben. The superserver is not the first process and comes after auxiliary write daemons. I also found multiple cases for instances that upgraded from Caché to IRIS where the first process uses cacheusr but the superserver uses irisusr. So this will not work. I think we may be stuck with looking for the superserver process.

score 0 · Answer 7 · 2025-03-14T11:55:43-04:00

See my reply to Ben, below. Unfortunately it seems the first process is not necessarily correct for instances with an upgrade history from Caché to IRIS.

score 1 · Answer 8 · 2025-03-13T19:19:27-04:00

There is a somewhat "simple" method too

/// search for the superserver job
/// return the OS Username for that job
ClassMethod OSUsername()
{
	new $namespace
	set $namespace="%SYS"
	
	set job=""
	for {set job=$zj(job) quit:job=""
		set prc=##class(%SYS.ProcessQuery).%OpenId(job)
		if prc, prc.JobType=24 ret prc.OSUserName
	}
	ret ""
}

score 2 · Answer 9 · 2025-03-13T21:12:28-04:00

Hi Evan,

i think the only way is using process query like this:

set currentUser = ##class(%SYS.ProcessQuery).%OpenId($job).OSUserName

score 2 · Answer 10 · 2025-03-14T02:46:15-04:00

You can use $ZF(-100) command to execute operative system commands (here an example), with that command you can look for the process that is locking the superserver.

score 1 · Answer 11 · 2025-03-14T08:04:31-04:00

Vitaliy Serdtsev · Mar 14

$SYSTEM.Process.UserName(##class(%SYS.ProcessQuery).NextProcess(""))

1 0