Yet Another Performance Puzzle

ROUTINE ztest22
Version()  quit 20250611
  ;
  ; do init^ztest22(100)  ; in one irissession
  ;
  ; in another irissession:
  ; set N=1E7 do runOne^ztest22("convertInRunFar",N,.fields) set dt1=$get(fields("dt")) do runOne^ztest22("convertInBigMacFar",N,.fields) set dt2=$get(fields("dt")) w $fn(dt2-dt1*100/dt1,"",2)_"% difference",!
  ;
runList(bKill,pList,pN)
  new iSample
  if $get(bKill,0) kill ^measure
  set pN=$get(pN,1E7)
  for iSample=1:1:$length(pList,",") do runOne($piece(pList,",",iSample),pN,.fields) merge ^measure($i(^measure))=fields
  quit
runOne(pOffset,pN,pFields) ; k  do runOne^ztest22("convertIn",1E6,.fields)
  new (pOffset,pN,pFields) ; to isolate sample's local symtab from other samples ones ;new N,i,textRef,rc,dt,pre,post,sample,category,comment
  set pN=$get(pN,1E5)
  if pOffset=+pOffset set textRef="meta+"_pOffset
  else  set textRef=pOffset
  set rc=$$getFields(textRef) if 'rc w "$text("_textRef_") does not exist",! goto runOneQ
  if pre'="" xecute pre
  if $get(N)="" set N="pN"
  if '$isValidNum(N) set N=@N
  if N=1 {
   set dt=$zhorolog
   xecute sample
   set dt=($zhorolog-dt)*1E6
  } elseif sample="set convertInx=$$convertIn^ztestLib(^mtempFF(i),""UTF8"")" {
   set dt0=$zhorolog
   for i=1:1:N set convertInx=""
   set dt0=($zhorolog-dt0)
   set dt=$zhorolog
   for i=1:1:N set convertInx=$$convertIn^ztestLib(^mtempFF(i),"UTF8")
   set dt=($zhorolog-dt-dt0)*1E6,dt=dt/N
  } elseif sample="set convertInx=$$convertIn^ztestLib(convertIny,""UTF8"")" {
   set dt0=$zhorolog
   for i=1:1:N set convertInx=""
   set dt0=($zhorolog-dt0)
   set dt=$zhorolog
   for i=1:1:N set convertInx=$$convertIn^ztestLib(convertIny,"UTF8")
   set dt=($zhorolog-dt-dt0)*1E6,dt=dt/N
  } else {
   set temp="set convertInx="""""
   set dt0=$zhorolog
   xecute "for i=1:1:N "_temp
   set dt0=($zhorolog-dt0)
   set dt=$zhorolog
   xecute "for i=1:1:N "_sample
   set dt=($zhorolog-dt-dt0)*1E6,dt=dt/N
  }
  write pOffset,?30,$fn(dt,"",3),?45,comment,!
  if post'="" xecute post
  do setFields(textRef,.pFields)
runOneQ
  quit
getFields(pLabel) ; w $$getFields^ztest22("convertIn"),! zwrite ; k  w $$getFields^ztest22("meta+"_1),! zwrite
  new meta,sep,fields,i,fieldName,field
  if $text(@pLabel)="" quit 0
  set meta=$text(meta)
  set sep=";~"
  set fields=$text(@pLabel)
  for i=2:1:$length(meta,sep) set fieldName=$piece(meta,sep,i),field=$piece(fields,sep,i) set @fieldName=field
  quit 1
setFields(pLabel,pFields) ; w $$setFields^ztest22("convertIn",.fields),!
  kill pFields
  set pFields("label")=pLabel
  set pFields("comment")=comment
  set pFields("dt")=dt
  quit 1
init(pInsertAfterN) ; do init^ztest22(0)
  set sc=$$createRoutine("ztestBigMac",32000,1900)
  if 'sc do $system.Status.DisplayError(sc)
  set sc=$$createProc("ztestLib",1500,200,1,.pInsertAfterN)
  if 'sc do $system.Status.DisplayError(sc)
  quit

/// pName - rtn name, pNLines - #lines, pNLabels - #labels, pInsertFunction - insert $$convertIn?, pInsertAfterNLabel - insert it after Nth label
createRoutine(pName,pNLines,pNLabels,pInsertFunction,pInsertAfterNLabel)
  new nPerLabel,nInsertAfterLabel
  set pInsertFunction=$get(pInsertFunction,0)
  set pInsertAfterN=$get(pInsertAfterN,pNLabels)
  do ##class(%Routine).Delete(pName_".MAC")
  set routine = ##class(%Routine).%New(pName_".MAC")
  ; Write lines of code to the routine
  do routine.WriteLine(pName)
  do routine.WriteLine("%New()")
  do routine.WriteLine(" quit """_pName_"""")
  set nPerLabel=pNLines\pNLabels-3 set:nPerLabel<=0 nPerLabel=1
  #; set nInsertAfterLabel=pInsertAfterN\nPerLabel
  if pInsertFunction&&(pInsertAfterNLabel=0) {
    do routine.WriteLine("convertIn(str,table)")
    do routine.WriteLine(" new handle,strout")
    do routine.WriteLine(" set strout=$zconvert(str,""I"",table,handle)")
    do routine.WriteLine(" quit strout_$select(handle="""":"""",1:""?"")")
    set pInsertFunction=0
  }
  for i=1:1:pNLabels {
    do routine.WriteLine("a"_i_"()")
    do routine.WriteLine(" new a"_i_",b"_i_",c"_i_",d"_i_",e"_i)
    for j=1:1:nPerLabel {
      do routine.WriteLine(" set a"_i_"="_j_" set b"_i_"="_j_" set c"_i_"="_j_" set d"_i_"="_j_" set e"_i_"="_j)
    }
    do routine.WriteLine(" quit a"_i)
    if pInsertFunction&&(i>=pInsertAfterNLabel) {
      do routine.WriteLine("convertIn(str,table)")
      do routine.WriteLine(" new handle,strout")
      do routine.WriteLine(" set strout=$zconvert(str,""I"",table,handle)")
      do routine.WriteLine(" quit strout_$select(handle="""":"""",1:""?"")")
      set pInsertFunction=0
    }
  }
  if pInsertFunction {
      do routine.WriteLine("convertIn(str,table)")
      do routine.WriteLine(" new handle,strout")
      do routine.WriteLine(" set strout=$zconvert(str,""I"",table,handle)")
      do routine.WriteLine(" quit strout_$select(handle="""":"""",1:""?"")")
      set pInsertFunction=0
  }
  ; save the routine
  do routine.Save()
  ; compile the routine
  set sc=routine.Compile("k")
  quit sc

/// pName - rtn name, pNLines - #lines, pNLabels - #labels, pInsertFunction - insert $$convertIn?, pInsertAfterNLabel - insert it after Nth label
createProc(pName,pNLines,pNLabels,pInsertFunction,pInsertAfterNLabel)
  new nPerLabel,nInsertAfterLabel
  set pInsertFunction=$get(pInsertFunction,0)
  set pInsertAfterN=$get(pInsertAfterN,pNLabels)
  do ##class(%Routine).Delete(pName_".MAC")
  set routine = ##class(%Routine).%New(pName_".MAC")
  ; Write lines of code to the routine
  do routine.WriteLine(pName)
  do routine.WriteLine("%New() [] Public")
  do routine.WriteLine("{ quit """_pName_""" }")
  set nPerLabel=pNLines\pNLabels-3 set:nPerLabel<=0 nPerLabel=1
  #; set nInsertAfterLabel=pInsertAfterN\nPerLabel
  if pInsertFunction&&(pInsertAfterNLabel=0) {
    do routine.WriteLine("convertIn(str,table) [] Public")
    do routine.WriteLine("{ set strout=$zconvert(str,""I"",table,handle)")
    do routine.WriteLine(" quit strout_$select(handle="""":"""",1:""?"") }")
    set pInsertFunction=0
  }
  for i=1:1:pNLabels {
    do routine.WriteLine("a"_i_"() [] Public")
    do routine.WriteLine(" {")
    for j=1:1:nPerLabel {
      do routine.WriteLine(" set a"_i_"="_j_" set b"_i_"="_j_" set c"_i_"="_j_" set d"_i_"="_j_" set e"_i_"="_j)
    }
    do routine.WriteLine(" quit a"_i_" }")
    if pInsertFunction&&(i>=pInsertAfterNLabel) {
      do routine.WriteLine("convertIn(str,table) [] Public")
      do routine.WriteLine("{ set strout=$zconvert(str,""I"",table,handle)")
      do routine.WriteLine(" quit strout_$select(handle="""":"""",1:""?"") }")
      set pInsertFunction=0
    }
  }
  if pInsertFunction {
    do routine.WriteLine("convertIn(str,table) [] Public")
    do routine.WriteLine("{ set strout=$zconvert(str,""I"",table,handle)")
    do routine.WriteLine(" quit strout_$select(handle="""":"""",1:""?"") }")
    set pInsertFunction=0
  }
  ; save the routine
  do routine.Save()
  ; compile the routine
  set sc=routine.Compile("k")
  quit sc
convertInLocal(str,table)
  #; quit $$convertIn^ztestLib(str,table)
  new handle,strout
  set strout=$zconvert(str,"I",table,handle)
  quit strout_$select(handle="":"",1:"?")

meta ;~category;~pre;~N;~sample;~post;~comment;~dt
convertInFF ;~convert;~;~pN;~set convertInx=$$convertIn^ztestLib(^mtempFF(i),"UTF8");~;~looping $$convertIn^ztestLib(^mtempFF(i)...)
convertInFFBigMac ;~convert;~set convertName=$$%New^ztestBigMac();~pN;~set convertInx=$$convertIn^ztestLib(^mtempFF(i),"UTF8");~;~%New^ztestBigMac + looping $$convertIn^ztestLib(^mtempFF(i)...)
convertInRunFar ;~convert;~set convertIny=$zcvt("Маленькая умная Коричневая Лиса прыгает через лежащую сонную Пятнистую Собаку","o","UTF8");~pN;~set convertInx=$$convertIn^ztestLib(convertIny,"UTF8");~;~looping $$convertIn^ztestLib (far)
convertInBigMacFar ;~convert;~set convertName=$$%New^ztestBigMac() set convertIny=$zcvt("Маленькая умная Коричневая Лиса прыгает через лежащую сонную Пятнистую Собаку","o","UTF8");~pN;~set convertInx=$$convertIn^ztestLib(convertIny,"UTF8");~;~%New^ztestBigMac, looping $$convertIn^ztestLib (far)