Some options:

• Check this example
• Use ZEN reports
• Produce CSV and use LibreOffice to convert CSV to XLSX. Article about this approach.
• Use Apache POI to generate XLSX. Here's Apache POI JGW wrapper and ObjectScript API but you'll need to extend it.

> - Utilize another language or library that has methods to parse the data into an Excel file (https://stackoverflow.com/questions/17684610/python-convert-csv-to-xlsx).

If you want to use Python from Cache, check PythonGateway.

If you want to transfer data via REST check RESTForms project (part 2).

Mimedata is subscripted by name and index.

So in your case:

set name = "BulkFileUpload"
for i=1:1:%request.CountMimeData(name)
    set mimeData = %request.GetMimeData(name, , i)
}

On each iteration mimeData variable would hold the stream with one next mimedata.

%request is simply an object of %CSP.Request class, check the docs or code to know how it works.

Additionally you can use this snippet to see what's inside %request, %response and %session objects:

set %response.ContentType = "html"
do ##class(%CSP.Utils).DisplayAllObjects()
quit $$$OK

<FILEFULL>  - Caché attempted to allocate a disk block for more global data or routine storage, but the attempt failed because the Caché database is full and could not be expanded.

Affected db is /hs-connect-hom/db/BPINTEGRADEV-GLB.

Bitmap indices maintain one node per each chunk of 64 000 id's, if at least one id from that range exists. So random integer ids can slow bitmaps down. On the other hand if there are two consecutive but spread (i.e 1..1000 and 100000...110000) id sequences it would generate just 2 global nodes so everything should be ok in that scenario.

Check index global in various scenarios:

Class Example.Bitmap Extends %Persistent
{

Property ID As %Integer(MINVAL = 1);

Property Value As %Integer(MAXVAL = 9, MINVAL = 0);

Index IDKEY On ID [ IdKey, Unique ];

Index ValueIndex On Value [ Type = bitmap ];

ClassMethod Populate(startid, endid, step = 1) As %Integer
{
    set count = 0
    do ..%KillExtent()
    for i = startid:step:endid {
        set count = count + 1
        set ^Example.BitmapD(i) = $lb("", $random(10))
    }
    
    do ..%BuildIndices()
    
    quit count
}

Query Select(value) As %SQLQuery
{
SELECT ID
FROM Example.Bitmap
WHERE Value = :value
}

/// do ##class(Example.Bitmap).Test()
ClassMethod Test()
{
    do ..TestOne(1, 1000000)
    do ..TestOne(100000000, 101000000)
    do ..TestOne(1, 1000000000, 1000)
}

ClassMethod TestOne(startid, endid, step = 1)
{
    set startTS = $zh
    set count = ..Populate(startid, endid, step)
    set endTS = $zh
    
    set populateTime = endTS - startTS
    
    set startTS = $zh
    set rs = ..SelectFunc($random(10))
    
    set endTS = $zh
    
    set queryTime = endTS - startTS
    
    write $$$FormatText("Start: %1, End: %2, Step: %3, Count: %4, Populate Time: %5, Query Time: %6", startid, endid, step, count, populateTime, queryTime),!
}
}

The easiest way is to use JSON_OBJECT for everything. Fastest would be just writing to device from resultset. Combine these approaches to get the performance you need (add this code to Parent class and call Test method):

Query Display() As %SQLQuery
{
SELECT
    JSON_OBJECT(
        'ID':%ID,
        'Name': Name,
        'Description': Description,
        'Children':    Example.Parent_GetChildrenInfo(%ID)
    )
FROM Example.Parent
}

/// do ##class(Example.Parent).Test()
ClassMethod Test(count = 0)
{
    if count>0 {
        do ##class(Example.Child).%KillExtent()
        do ..%KillExtent()
        
        
        do ##class(Example.Child).Populate(count,,,,$$$NO)
        do ..Populate(count,,,,$$$NO)
    }
    
    do ..DisplayFunc().%Display()
}

ClassMethod GetChildrenInfo(id) As %String [ SqlProc ]
{
    #define CRLF                             $c(13,10)
    #define ZENJSISNUM(%val)                ($IsValidNum(%val)&&(%val=+(%val)))
    #define ZENJSNUM(%num)                    $fnumber(%num,"LON")
    #; JSON utility macros that use the JSON translation table instead of the JS translation table
    #define ZENJSTABLE(%format)                ("JS"_$S(%format["u":"ML",1:""))
    #define ZENJSONTABLE(%format)            ("JSON"_$S((%format["u"):"ML",1:""))
    #define ZENJSONESCAPE(%str,%format)        $S(%format["s":$ZCVT(%str,"O",$$$ZENJSONTABLE(%format)),1:$Replace($ZCVT(%str,"O",$$$ZENJSTABLE(%format)),"\'","'"))
    #define ZENJSONSTR(%str,%format)        (""""_$$$ZENJSONESCAPE(%str,%format)_"""")
    #define ZENJSONPROP(%prop,%format)        $$$ZENJSONSTR(%prop,%format)
    #define ZENJSONVALUE(%val,%format)        $S($$$ZENJSISNUM(%val):$$$ZENJSNUM(%val),$C(0)=(%val)||$ListValid(%val):"""""",1:$$$ZENJSONSTR(%val,%format))
    #define ZENJSONPAIR(%pr,%val,%format)    $$$ZENJSONPROP(%pr,%format)_":"_$$$ZENJSONVALUE(%val,%format)
    
    set out = "["   
    
    
    set ids = ..ChildrenGetStored(id)
    set ptr=0
    set separator=0
    while $listnext(ids,ptr,value) {
        set value = $lg(value)
        set:separator out = out _ ","

        set out = out _  "{"
        set out = out _  $$$ZENJSONPAIR("Name",##class(Example.Child).NameGetStored(value),"") _","
        set out = out _  $$$ZENJSONPAIR("Description",##class(Example.Child).DescriptionGetStored(value),"")
        set out = out _  "}"
        set separator = 1
    }
    
    set out = out _  "]"
    
    quit out
}