Subclasses and/or Inheritence

Question

Question

Steve Hayworth · Mar 25, 2019

#Beginner #Data Model #Object Data Model #Caché

First time post, also a new Cache developer, hence the <Beginner> tag.

If our data has Predefined terms in a dictionary, and a user can add terms on their own, can the terms exist in different tables?

Lets call the tables "Terms" and the user data in "UserTerms".

If a third class definition has a property of "Term" can it not be either Terms or UserTerms?

I'm leaning towards using a Subclass strategy where the pseudo "Parent" (forgive me) is Dictionary.Term and the child is along the lines of Dictionary.Term.User

Dictionary.Term.User can inherit from Dictionary.Term and this is stated in the Docs "If class B inherits from class A, you can use an instance of class B in any location where you can use an instance of class A."

This applies to properties of a class correct? Not just methods?

Is there an alternative data model for this that would support the access to the predefined terms to be in a read-only database so as to protect them from changes, yet the users can add terms all they want?

Discussion (5)0

Log in or sign up to continue

Andre Cerri · Mar 27, 2019

Interestingly, I am researching this for a customer. Another way to do this that I have seen is to seed the ID counter at the site to a really high number (e.g. set ^Vendor.CountryD=10000000) after the initial Country code table is deployed. Then, new entries that are distributed by the vendor will never have conflicting IDs (assuming no more than 10000000 entries are ever shipped of course). But this also means that you can't ship the whole vendor copy of the global as you will overwrite the onsite ID counter node.

And, in a multi-tenant/namespace deployment you can't generate SQL or Object Insert scripts - if you have indices on the table then they need to be built locally for each namespace and global mapped and so you would need to run the insert script on each namespace to maintain the indices. However, rebuilding the indices on code tables should be pretty quick as they tend not to be huge, and hopefully won't balloon the journals too much....

I like the idea of a read-only distributed database - oddly I hadn't thought of that as an extra layer of protection beyond what the application code may provide

The biggest issue with this approach though is likely to be the risk of a unique property collision - customer adds MYNewCountry , and then at some point so does the Vendor. And so an upgrade script would have to check for that - possibly renaming the customer object to say MyNewCountryX.

0 0

Eduard Lebedyuk · Mar 28, 2019

Bitmap indices maintain one node per each chunk of 64 000 id's, if at least one id from that range exists. So random integer ids can slow bitmaps down. On the other hand if there are two consecutive but spread (i.e 1..1000 and 100000...110000) id sequences it would generate just 2 global nodes so everything should be ok in that scenario.

Check index global in various scenarios:

Example.Bitmap

Class Example.Bitmap Extends %Persistent
{

Property ID As %Integer(MINVAL = 1);

Property Value As %Integer(MAXVAL = 9, MINVAL = 0);

Index IDKEY On ID [ IdKey, Unique ];

Index ValueIndex On Value [ Type = bitmap ];

ClassMethod Populate(startid, endid, step = 1) As %Integer
{
    set count = 0
    do ..%KillExtent()
    for i = startid:step:endid {
        set count = count + 1
        set ^Example.BitmapD(i) = $lb("", $random(10))
    }
    
    do ..%BuildIndices()
    
    quit count
}

Query Select(value) As %SQLQuery
{
SELECT ID
FROM Example.Bitmap
WHERE Value = :value
}

/// do ##class(Example.Bitmap).Test()
ClassMethod Test()
{
    do ..TestOne(1, 1000000)
    do ..TestOne(100000000, 101000000)
    do ..TestOne(1, 1000000000, 1000)
}

ClassMethod TestOne(startid, endid, step = 1)
{
    set startTS = $zh
    set count = ..Populate(startid, endid, step)
    set endTS = $zh
    
    set populateTime = endTS - startTS
    
    set startTS = $zh
    set rs = ..SelectFunc($random(10))
    
    set endTS = $zh
    
    set queryTime = endTS - startTS
    
    write $$$FormatText("Start: %1, End: %2, Step: %3, Count: %4, Populate Time: %5, Query Time: %6", startid, endid, step, count, populateTime, queryTime),!
}
}

0 0

score 0 · Answer 1 · 2019-03-26T02:59:41-04:00

This applies to properties of a class correct? Not just methods?

Correct.

You have several solutions:

Application level control. You have one table Term { Name, Type} and on the application level you decide for edits to go or not based on type. It is the fastest solution, but you need to write a application code and remember to check for type.
Class-level control as described by you.
Row-level security. Control access row by row.

score 0 · Answer 2 · 2019-03-27T14:12:42-04:00

But this also means that you can't ship the whole vendor copy of the global as you will overwrite the onsite ID counter node.

You can! When you load globals specify /mergeglobal flag to merge the global with existing data instead of overwriting it:

set sc = $system.OBJ.Load("global.xml", "/mergeglobal=1")

seed the ID counter at the site to a really high number

Bitmap indices would really slow down from that.

score 0 · Answer 3 · 2019-03-28T09:40:11-04:00

Hey Eduard

I didn't know about /mergeglobals, thanks!

As for Bitmap Indices, I doubt you would even use them on small dictionary like tables, and even then you would likely only have one global node per index, right? So not sure why you think this - can you explain?

andre