Export production documentation to Archimate model?

/// Settings common for all Interoperability BH
Query defaultSettings() As %Query
{
SELECT
   prop.name "Setting",
   TRIM('"' FROM MAX(prop.InitialExpression)) "Default value",
   LIST(prop.parent) "Class",
   MAX(prop.Description) "Description"
FROM "%Dictionary".PropertyDefinition prop
JOIN "%Dictionary".CompiledParameter par ON par.parent = prop.parent AND par.Name = 'SETTINGS'
JOIN "%Dictionary".CompiledClass cls ON prop.parent = cls.Name
WHERE (cls.Super LIKE '%Ens.Host%' OR cls.Name = 'Ens.Host' OR cls.Name = 'Ens.BusinessProcessBPL') AND
       par."_Default" LIKE '%' || prop.Name || '%'
GROUP BY prop.Name
ORDER BY 1
}

/// User BH classes
Query productionClasses() As %Query
{
SELECT
   Name "Class",
   Description "Description"
FROM "%Dictionary".CompiledClass cls
WHERE Name LIKE '%'
       AND Super In ('Ens.BusinessProcessBPL', 'Ens.BusinessService', 'Ens.BusinessOperation', 'Ens.BusinessProcess')
ORDER BY 1
}

/// Settings for User BH
Query productionClassesSettings() As %Query
{
SELECT
   prop.parent "Class",
   prop.name "Setting",
   TRIM('"' FROM prop.InitialExpression) "Default value",
   prop.Description "Description"
FROM "%Dictionary".PropertyDefinition prop
JOIN "%Dictionary".CompiledParameter par ON par.parent = prop.parent AND par.Name = 'SETTINGS'
JOIN "%Dictionary".CompiledClass cls ON prop.parent = cls.Name
WHERE cls.Name LIKE '%' AND par."_Default" LIKE '%' || prop.Name || '%'
ORDER BY 1,2
}


/// Production elements
Query productionItems(production) As %Query
{
SELECT
   Name,
   ClassName
   /*,Comment*/
FROM Ens_Config.Item
WHERE Production = :production
}

/// Get settings of production item
Query productionItemsSettingsCall(production) As %Query
{
SELECT *
FROM User_util.productionItemsSettings(:production)
}

/// Custom query - get settings for production items
Query productionItemsSettings(production As %String) As %Query(CONTAINID = 0, ROWSPEC = "Element:%String,Setting:%String,Host:%String,Value:%String") [ SqlName = productionItemsSettings, SqlProc ]
{
}

ClassMethod productionItemsSettingsExecute(ByRef qHandle As %Binary, production As %String) As %Status
{
    set obj = ##class(Ens.Config.Production).%OpenId(production,,.sc)
    quit:$$$ISERR(sc) sc
    do ..clearProductionItems(.obj)
    set qHandle("production") = obj
    set qHandle("item") = 1
    set qHandle("itemCount") = qHandle("production").Items.Count()

    set qHandle("setting") = 1
    set qHandle("settingCount") = qHandle("production").Items.GetAt(qHandle("item")).Settings.Count()
    quit sc
}

ClassMethod productionItemsSettingsFetch(ByRef qHandle As %Binary, ByRef Row As %List, ByRef AtEnd As %Integer = 0) As %Status [ PlaceAfter = productionItemsSettingsExecute ]
{
        #dim sc As %Status = $$$OK
        #dim item As Ens.Config.Item = qHandle("production").Items.GetAt(qHandle("item"))
        #dim setting As Ens.Config.Setting = item.Settings.GetAt(qHandle("setting"))

        set AtEnd = 0
        set Row = $lb(item.Name, setting.Name, setting.Target, setting.Value)
       
        if qHandle("setting")<qHandle("settingCount") {
                set qHandle("setting") = qHandle("setting") + 1
        } else {
                if qHandle("item")<qHandle("itemCount") {
                        set qHandle("item") = qHandle("item") + 1
                        set qHandle("setting") = 1
                        set qHandle("settingCount") = qHandle("production").Items.GetAt(qHandle("item")).Settings.Count()
                } else {
                        set AtEnd = 1
                }
        }
       
     quit sc
}

/// Remove production items without settings.
ClassMethod clearProductionItems(ByRef production As Ens.Config.Production)
{
    #dim item As Ens.Config.Item
    for i = production.Items.Count():-1:1 {
        set item = production.Items.GetAt(i)
        do:item.Settings.Count()=0 production.Items.RemoveAt(i)
    }
}