Class parameter in class query

Question

Question

Ruslan K · Oct 7, 2017

Is it possible to use a class parameter in class query?

Example:

Class SomeClass
{

Parameter SOMENAME = "Name1";

Query SomeQuery() As %SQLQuery
{
SELECT ID || ..#SOMENAME  || Name FROM Table
}

}

Discussion (3)0

Log in or sign up to continue

Vitaliy Serdtsev · Oct 9, 2017

Class dc.SomeClass
{

Parameter SOMENAME = "Name1";

Query SomeQuery(SOMENAME = {..#SOMENAME}) As %SQLQuery
{
  SELECT ID || :SOMENAME || Name FROM Table1
}

Query SomeQuery1() As %SQLQuery
{
  #define SOMENAME ##Expression("'"_$parameter("dc.SomeClass","SOMENAME")_"'")
  SELECT ID || $$$SOMENAME || Name FROM Table1
}

Query SomeQuery2() As %SQLQuery
{
  #define SOMENAME ##Expression("'"_##class(dc.SomeClass).#SOMENAME_"'")
  SELECT ID || $$$SOMENAME || Name FROM Table1
}

ClassMethod Test()
{
  ;d ##class(dc.SomeClass).Test()
  
  s rs=##class(%ResultSet).%New("dc.SomeClass:SomeQuery")
  s sc=rs.Execute()
  i $$$ISERR(sc) {
    d $System.Status.DisplayError(sc)
  } else {
    d rs.%Display()
  }
}
}

4 0

score 0 · Answer 1 · 2017-10-07T11:39:17-04:00

This can be done with SQL procedure:

Query SomeQuery() As %SQLQuery
{
SELECT ID || SomeClass.GetParam('SomeClass', 'SOMENAME') FROM Table
}

ClassMethod GetParam(class, param) As %String [ CodeMode = expression, SqlProc ]
{
$parameter(class, param)
}

score 0 · Answer 2 · 2019-11-14T07:46:21-05:00

Fantastic help. Thank for sharing this. I didn't know you could use ##Expression in basic class queries. Studio does complain about it though but works just fine at run time!