Ens.Director classmethods GetAdapterSettingValue  & GetHostSettingValue could be used - they account for System Default Settings as well. Need to know if the setting is from the Adapter or the Host class (see also GetItemSettingValue that takes Adapter or Host as the type parameter).

set hostitem="SFTPToSomewhere",username=##class(Ens.Config.Credentials).%OpenId(##class(Ens.Director).GetAdapterSettingValue(hostitem,"Credentials",.sc)).Username
write
hostitem="SFTPToSomewhere"
sc=1
username="mlm"

Going off on a tangent one can use the Ens.Setting.Reporter class that is the basis for the Port Authority to find all Credentials in the production:

set reporter=##class(Ens.Setting.Reporter).%New()
set reporter.SettingNamePattern="Credentials"
set reporter.SettingReportClass="Ens.Setting.Report.base"
set sc=reporter.SearchSettings()

The results are in multidimensional property reporter.LocalResults with setting name being lowercase:
LocalResults("MYNAMESPACE","items",1,"categories") = "rest"
LocalResults("MYNAMESPACE","items",1,"credentials") = "JGM"
LocalResults("MYNAMESPACE","items",1,"document") = "primary"
LocalResults("MYNAMESPACE","items",1,"enabled") = 0
LocalResults("MYNAMESPACE","items",1,"itemName") = "EnsLib.REST.GenericOperation"
LocalResults("MYNAMESPACE","items",1,"partner") = ""
LocalResults("MYNAMESPACE","items",2,"categories") = ""
LocalResults("MYNAMESPACE","items",2,"credentials") = "MLM"
LocalResults("MYNAMESPACE","items",2,"document") = "primary"
LocalResults("MYNAMESPACE","items",2,"enabled") = 0
LocalResults("MYNAMESPACE","items",2,"itemName") = "SFTPToSomewhere"
LocalResults("MYNAMESPACE","items",2,"partner") = ""

I vote for #1 (except need to  'grovel' and hope to work towards removing that sentiment)

Here are some proposed enslib fixes and an example of using a custom search table to index data from the generic message that can be used in the current message search. The following is not intended to detract from the need to amend enslib code to prevent a headache by allowing searching for data within GenericMessage objects out of the box.

For the hard coded EnsLib.HTTP.GenericMessage:

In EnsLib.HTTP.GenericService:

Adding:

Property MessageClass As %String [ InitialExpression = "EnsLib.HTTP.GenericMessage" ];

Expose via Settings by including in SETTINGS parameter

MessageClass:Basic:selector?multiSelect=0&context={Ens.ContextSearch/SubclassOf?class=EnsLib.HTTP.GenericMessage&include=1}

Amend hard coded line to:

Set tRequest=$classmethod(..MessageClass,"%New",pRequestBody,,pRequestBody)

The SETTINGS include=1 is another limitation correction arising from this as Ens.ContextSearch/SubclassOf does include the super class parameter

Ens.ContextSearch method SubclassOf add the super class as a valid choice

If tClass '= "" {
    If $G(pParms("include")) Set pResults($I(n))=tClass

We ought to also expose the SearchTable property since this would allow indexing data from the source without creating a custom service to merely set the SearchTable class.

Adding to SETTINGS parameter:

SearchTableClass:Basic:selector?multiSelect=0&context={Ens.ContextSearch/SubclassOf?class=Ens.CustomSearchTable}

Example of a CustomSearchTable class:

Class JGM.CustomSearchTable Extends Ens.CustomSearchTable
{
Parameter DOCCLASS = "EnsLib.HTTP.GenericMessage";
/// This is the case id from the REST payload
Property CaseId As %String(MAXLEN = "");
Index CaseIdIdx On CaseId;
/// Example to index a JSON path value from the Stream property
ClassMethod OnIndexDoc(pDocObj As %Persistent, pSearchTable As Ens.CustomSearchTable) As %Status
{
    Set sc = $$$OK
    Try {
        Set json = {}.%FromJSON(pDocObj.Stream)
        Set caseId = json.%Get("case")
    } Catch ex {
        /*  can decide if want to populate sc from ex 
            if do not want to suppress error
        */
        Set caseId = "UNKNOWN"
    }
    /* Can prevent saving a search table entry if appropriate */
    If (caseId = "UNKNOWN")||(caseId = "") {
        Set pSearchTable=""
    } Else {
        Set pSearchTable.CaseId = caseId
    }
    Return sc
}

One can use a Transformation to populate pSearchTable in OnIndexDoc but still need to create the search table class with properties and hard code the transformation in the search table class.

Apologies if too late but I tried the following based on the Non Persistence option used in the EnsLib.HTTP/REST/SOAP Generic classes (also see  Accelerate Ensemble)

1. Custom TCP Service Extends EnsLib.HL7.Service.TCPService:

Class Community.NonPersistService Extends EnsLib.HL7.Service.TCPService
{

Parameter SETTINGS = "PersistInProcData:Additional";

/// Persist data to operations with invocation InProc<br/>
/// The default is On. <br/>
/// This setting is only used if calling an operation with invocation InProc. <br/>
/// If this setting is off then no message headers will be created and message bodies will not be saved.<br/>
/// If this setting is off there will be no trace in the message viewer. <br/>
/// If this setting is off there will be no retry attempts by the operation - only one attempt will be made. <br/> 
Property PersistInProcData As %Boolean [ InitialExpression = 1 ];

Method OnInit() As %Status
{
    Set $$$EnsInProcPersist=..PersistInProcData
    Quit ##super()
}

}

2. Custom HL7 File Operation invoked InProc that is the target of the service

Class Community.InProcOperation Extends EnsLib.HL7.Operation.FileOperation
{

Parameter INVOCATION = "InProc";

}

Note the property description from EnsLib.HTTP.GenericService for PersistInProcData states for synchronous sends but this needs to be removed since not relevant for InProc. Sufficient that InProc target processed via OnMessage.

Greetings, When using the EnsLib.SOAP.InboundAdapter to provide the SOAP service on a dedicated TCP port one is bypassing the Web Gateway and hence %session is not available. (SOAP InboundAdapter docs)

I am doing work with Caché LDAP support  and am benefiting from using the  Apache DS and Apache Directory  Studio plug-in (http://directory.apache.org/studio/update) with Atelier.

See class method EnsLib.Testing.Service::SendTestRequest() that allows one to issue the test from terminal without having to add another component.

classmethod SendTestRequest(pTarget As %String, pRequest As Ens.Request, ByRef pResponse As Ens.Response, Output pSessionId As %String, pGetReply As %Boolean = 0) as %Status

    Send a test request to the specified target host (BusinessProcess or BusinessOperation). 

Thanks Scott,

Our EnsLib.HL7.Service.FTPService uses the FilePath setting in the Source information which does not account for the sub directory searching option:

OnProcessInput() line:

Set tIOStream.Name=pFTPStream.Attributes("Filename")_$C(13,10)_"via FTP "_..Adapter.FTPServer_":"_..Adapter.FTPPort_" path '"_..Adapter.FilePath_"'"
 

But the adapter is passing the actual path where the file was retrieved from in pFTPStream.Attributes("FTPDir") . I will make the change in EnsLib.HL7.Service.FTPService to use  pFTPStream.Attributes("FTPDir") instead of ..Adapter.FilePath but I am afraid I cannot advise on which release this will be in.

To verify from terminal using  write  ##class(EnsLib.HL7.Message).%OpenId(<id>).Source

returns before the code change:

somefile.hl7
via FTP 192.168.224.100:2121 path '/hl7'

to

somefile.hl7
via FTP 192.168.224.100:2121 path '/hl7/1/yellow/'

Would this be sufficient for your needs or since you state the reasons are more complicated  a more elegant solution in the Ensemble service is needed.

Kind regards

James