New post
Article
· Jan 7 1m read

Remove deleted classes after import

#Continuous Delivery #Continuous Integration #Source Control #InterSystems IRIS

When you deploy code from a repo, class (file) deletion might not be reflected by your CICD system.
Here's a simple one-liner to automatically delete all classes in a specified package that have not been imported. It can be easily adjusted for a variety of adjunct tasks:

set packages = "USER.*,MyCustomPackage.*"
set dir = "C:\InterSystems\src\"
set sc = $SYSTEM.OBJ.LoadDir(dir,"ck", .err, 1, .loaded)
set sc = $SYSTEM.OBJ.Delete(packages _ ",'" _ $LTS($LI($LFS(loaded_",",".cls,"), 1, *-1), ",'"),, .err2)

The first command compiles classes and also returns a list of loaded classes. The second command deletes all classes from specified packages, except for the classes loaded just before that.

Discussion (7)5
Log in or sign up to continue
Corentin Blondeau · Jan 13

 Hello,

I have an other way to do it, it's a (little) bigger.
It doesn't need to indicate the package at the beginning.

The little addition is that this method can return all the classes that are differents without delete them.
 

/// Take as parameters 
/// ClassList whitch is the list return by ImportDir
/// pDeleteIfExist : boolean to know if we have to delete classes
/// listClassDiffer : lists of differents classes between the directory from ImportDir and InterSystems
/// Return listClassDiffer; if error, return an exception
ClassMethod SynchroClass(ByRef classList As %String, pDeleteIfExist As %Boolean = 0, Output listClassDiffer As %ListOfDataTypes) As %Status
{
	Set status = $$$OK
	#dim exception As %Exception.AbstractException
	Set tKey = ""
	Set listclass = ##class(%ListOfDataTypes).%New()
	Set listClassDiffer = ##class(%ListOfDataTypes).%New()

	Try{
		// insert the differentes classes from classList in a new list with a "while"
		Do{
			Set tKey=$ORDER(classList(tKey))
			//Write " tkey " ,tKey,!
			Do listclass.Insert(tKey)
		}While(tKey'="")

		Set SQLquery = "SELECT Name "
		Set SQLquery = SQLquery _ " FROM %Library.RoutineMgr_StudioOpenDialog('*.cls',1,1,0,1,0,0,,,0) "		
		Set stmt = ##class(%SQL.Statement).%New()
		Set status = stmt.%Prepare(SQLquery)		
		Set rset = stmt.%Execute()
		#dim rset as %SQL.StatementResult 
		
		/* get the table of result of the SQL request as classes of server and compare them to the classes from listclass
		if classes are different, we add them to the zreturn's parameter and we delete them */
		While rset.%Next(){
			Set name = rset.%Get("Name")
	
			//Write " name class and index ", name,idx, !
			If (listclass.Find(name) = ""){
				Write !,name
				Set status = listClassDiffer.Insert(name)
				$$$ThrowOnError(status)

				If (pDeleteIfExist){
					Set status = $SYSTEM.OBJ.Delete(name,"e")
					$$$ThrowOnError(status)
				}				
			}		
		}
	}Catch exception {
		Set status = exception.AsStatus()
	}
	Quit status
}
0 0