New post
Question
· Jul 23, 2017

German collation of ß in upper and lower case in Cache 2017

#Caché #InterSystems IRIS

Recently upper case ß was defined as an official character for German
how can this be adjusted in Caché 2017 ?

Discussion (5)1
Log in or sign up to continue
Vitaliy Serdtsev · Jul 25, 2017

You can fix this error directly now, if you don't want to wait for the release of version 2018.1.1.

To do this, follow these steps:

  1. make export the locale "deuw" 
    %SYS>s Locales("deuw")="" d $system.OBJ.DisplayError(##class(Config.NLS.Locales).ExportList("loc_deuw.xml",.t,.Locales)) zw Locales,t
  2. fix the file loc_deuw.xml (by default located in the folder %CACHEHOME%\Mgr)
    Name of subtable
    (Where to insert)    		 New lines
    (That to insert)
    Add the following lines to the appropriate subtables:
    COL-German3-Unicode <FromToItem FromToKey="55,55,1">83,83;</FromToItem>
    <FromToItem FromToKey="55,55,2">7838;</FromToItem>
    <FromToItem FromToKey="55,55,3">83,7838;</FromToItem>
    COL-Unicode-German3 <FromToItem FromToKey="7838">55,55;2</FromToItem>
    <FromToItem FromToKey="83,83">55,55;1</FromToItem>
    <FromToItem FromToKey="83,7838">55,55;3</FromToItem>
    LowerCase-Unicode-Unicode <FromToItem FromToKey="7838">223</FromToItem>
    UpperCase-Unicode-Unicode <FromToItem FromToKey="223">7838</FromToItem>
  3. import fixed loc_deuw.xml:
    %SYS>d $system.OBJ.DisplayError(##class(Config.NLS.Locales).ImportAll("loc_deuw.xml",.t,1+2+4)) zw t
%SYS>d $system.OBJ.DisplayError(##class(Config.NLS.Locales).Compile("deuw"))
%SYS>d Locale^NLSLOAD("deuw")

    Just in case, restart Caché.

Now, run a small test

#include %systemInclude
#include %occErrors
#include %syNLS
test() public {
  
  #dim ex As %Exception.AbstractException

  try {
    $$$AddAllRoleTemporaryInTry
    n $namespace
    s $namespace="%SYS"
    
    s oldLocale=$$$LOCALENAME
    w "Old locale = ",oldLocale,!
    d ##class(Config.NLS.Locales).Install("deuw")
    w "Current locale = ",$$$LOCALENAME,!!
    
    k ^||low,^||up

    f w="wei"_$c(223)_"er","weiter","weiser" {
      s ^||low($zcvt(w,"L"))=1
      s ^||up($zcvt(w,"U"))=1
    }
    zw ^||low,^||up
    
    s low=$c(223)
    s up=$zcvt(low,"U")
    zw low,up
    zzdump low,up
    
  }catch(ex) {
    w "Error ", ex.DisplayString(),!
  }
  d ##class(Config.NLS.Locales).Install(oldLocale)

}

My result:

USER>d ^test
Old locale = rusw
Current locale = deuw
 
^||low("weiser")=1
^||low("weißer")=1
^||low("weiter")=1
^||up("WEISER")=1
^||up("WEIẞER")=1
^||up("WEITER")=1
low="ß"
up="ẞ"
 
0000: DF                                                      ß
0000: 1E9E                                                    ẞ
4 0