File size limit for upload/download

Yes, we create a component in javaScript, it sends a CACHE function to the text file, the internal function created in CACHE, this text is converted to base 64, and then we save the text (url of the file) .

ClassMethod enviarAnexo(idEncriptado As %String, nomeArquivo As %String, streamArquivo As %CSP.CharacterStream) As %String
{
    #dim id AS %String
    #dim resposta AS %String = ""
    #dim exception AS %Exception.AbstractException
    #dim estimativa AS EstimativaPrecoVenda    

    try {
        set id = ##class(%CSP.Page).Decrypt( idEncriptado )        
        if (..%ExistsId(id)){
            set estimativa =  ..%OpenId(id)            
             do estimativa.anexo.send(nomeArquivo, streamArquivo)            
             do estimativa.%Save()
            set resposta = $$$OK
        }
    } catch exception {
        set resposta = $$$FormatText("%1 - %2",exception.Name, exception.Data)
    }
    
    quit resposta
}

Method send(nameFile As %String, streamFile As %CSP.CharacterStream) As %Status
{
    #dim stream As %FileBinaryStream    
    set stream = ##class(GlobalBinaryStreamUtil).convertDataStream( streamFile )
    
    do ##class(GlobalBinaryStreamSpec).validateNameFile( nameFile )
    do ##class(GlobalBinaryStreamSpec).validateExtensionFile( nameFile )
    do ##class(GlobalBinaryStreamSpec).validateSizeFile( stream.Size )
    
    do ..strnameSet( ##class(GlobalBinaryStreamUtil).sanitizeName(nameFile) )
    do ..objfile.CopyFromAndSave( stream )
    
    quit $$$OK
}

ClassMethod convertDataStream(streamFile As %CSP.CharacterStream) As %FileBinaryStream
{
    #dim stream As %FileBinaryStream
    #dim text As %String
    
    set stream  = ##class(%FileBinaryStream).%New()
    if ($isObject(streamFile)){        
        set text = streamFile.Read( streamFile.Size )
        do stream.Write( ..convertTextPlain( text ) )
    } else {
        do stream.Write( ..convertTextPlain( streamFile ) )
    }
    quit stream
}

ClassMethod convertTextPlain(streamFile As %String) As %String [ Private ]
{
    #dim textPlain As %String
    #dim exception AS %Exception.AbstractException
    
    try {
        set textPlain = $SYSTEM.Encryption.Base64Decode(streamFile)
    } catch exception {
        if ( exception.Name = "<ILLEGAL VALUE>"){
            set textPlain = streamFile
        } else {
            throw exception
        }
    }
    quit textPlain
}

ClassMethod sanitizeName(nameFile As %String) As %String
{
    quit $translate(nameFile," ","_")
}